Issue with vbscript emailing, unable to generate text body - email

Question

So I'm trying to send an e-mail with VBscripting and otherwise it works fine, but nothing I try to write to the txt or html body, appear on the message. Here is the function I'm using:
Function EMail( myFrom, myTo, mySubject, myTextBody, myHTMLBody, myAttachment, mySMTPServer, mySMTPPort )
' This function sends an e-mail message using CDOSYS
'
' Arguments:
' myFrom = Sender's e-mail address ("John Doe <jdoe#mydomain.org>" or "jdoe#mydomain.org")
' myTo = Receiver's e-mail address ("John Doe <jdoe#mydomain.org>" or "jdoe#mydomain.org")
' mySubject = Message subject (optional)
' myTextBody = Actual message (text only, optional)
' myHTMLBody = Actual message (HTML, optional)
' myAttachment = Attachment as fully qualified file name, either string or array of strings (optional)
' mySMTPServer = SMTP server (IP address or host name)
' mySMTPPort = SMTP server port (optional, default 25)
'
' Returns:
' status message
'
' Standard housekeeping
Dim i, objEmail
' Use custom error handling
On Error Resume Next
' Create an e-mail message object
Set objEmail = CreateObject( "CDO.Message" )
' Fill in the field values
With objEmail
.From = myFrom
.To = myTo
' Other options you might want to add:
' .Cc = ...
' .Bcc = ...
.Subject = mySubject
.TextBody = myTextBody
.HTMLBody = myHTMLBody
If IsArray( myAttachment ) Then
For i = 0 To UBound( myAttachment )
.AddAttachment Replace( myAttachment( i ), "\", "\\" ),"",""
Next
ElseIf myAttachment <> "" Then
.AddAttachment Replace( myAttachment, "\", "\\" ),"",""
End If
If mySMTPPort = "" Then
mySMTPPort = 25
End If
With .Configuration.Fields
.Item( "http://schemas.microsoft.com/cdo/configuration/sendusing" ) = 2
.Item( "http://schemas.microsoft.com/cdo/configuration/smtpserver" ) = mySMTPServer
.Item( "http://schemas.microsoft.com/cdo/configuration/smtpserverport" ) = mySMTPPort
.Update
End With
End With
' Return status message
If Err Then
EMail = "ERROR " & Err.Number & ": " & Err.Description
Err.Clear
Else
objEmail.send
If Err Then
EMail = "ERROR " & Err.Number & ": " & Err.Description
Err.Clear
Else
EMail = "ok"
End If
End If
' Release the e-mail message object
Set objEmail = Nothing
' Restore default error handling
On Error Goto 0
End Function
And here is how I'm calling it:
MsgBox Email ( "address#sender.com", _
address#receiver.com, _
"This subject appears on the email correctly", _
"But this txt body does not", _
"", _
"", _
"mail.smtp-server.com", _
25 )
Like I said, the e-mail goes through alright, attachments work, subject works but for whatever reason the body never appears in the message! What is the problem?

Answer 1

For text use TextBody, for HTML use HTMLBody don't set both, currently you set HTMLBody to "" which will override TextBody.
You could use a flag argument;
Function EMail( myFrom, myTo, mySubject, myBody, isHTML, myAttachment...
Then
if isHTML then
.HTMLBody = myBody
else
.TextBody = myBody
end if