What does translate() with multiple parameters do? - openscad

Question

I accidentally left off the square brackets in a translate vector. Instead of causing an error, OpenSCAD silently ignored the error.
Is there some special meaning to translate() with multiple parameters? What should the second line do? I've attached an image showing the results I'm getting.
translate([5,5,-25]) color("red") cube([10,10,50]);
translate(5,5,-25) color("blue") cube([10,10,50]);

Answer 1

The translate "moves" one object from one Cartesian point to another.
The translate function always expects an array at his first parameter (named v, the array with our x,y and z coordinates).
Any function call in openscad can be written without the parameter name UNLESS you do use an different argument position.
So, using the translate function as example:
translate(0)
// ignored, first parameter is not an array.
cube([5,5,5]);
translate(v=5)
// ignored, v is not an array.
cube([5,5,5]);
translate([10,10,10])
// normal call.
cube([5,5,5]);
translate(v=[10,10,10])
// named parameter call.
cube([5,5,5]);
translate(1,2,3,4,5,6,7,8,9,0,infinite,v=[15,15,15])
// it works! we named the parameter, so
// openscad doesn't care about it's position!
cube([5,5,5]);
translate(1,2,3,4,5,6,7,8,9,0,[20,20,20])
// ignored, the first parameter is not an array
// AND v is not defined in this call!
cube([5,5,5]);
// At this point there are 3 cubes at the same position
// and 3 translated cubes!
test();
test(1);
test(1,2);
test(1,2,3);
test(1,2,3,4);
// 01) There is no function overwrite in openscad (it doesn't care about the number of parameters to
// 02) The function names are resolved at compile time (only the last one will be recognized).
module test(p1,p2,p3) echo( "test3" );
module test(p1,p2) echo( "test2" );
module test(p1) echo( "test1" );
OpenScad uses this syntax everywhere, not only in the translate function call.
Now your two lines:
translate([5,5,-25]) // executed, cube moved to x=5,y=5,z=-25
color("red") // executed
cube([10,10,50]); // executed, default creation pos x=0,y=0,z=0
translate(5,5,-25) // ignored, cube not moved.
color("blue") // executed
cube([10,10,50]); // executed, default creation pos x=0,y=0,z=0