Using NET::SMTP in Perl to send .OFT templates - perl

Question

I currently have a working Perl code that fires off an email to the correct email address with my generic subject and content.
However, currently whenever a new user starts, we fire off a premade .oft template that says everything that they need to know. The .oft is stored on our server. I was wondering is there a way to alter the perl code to make it so it takes the to: but uses the .oft template to make the rest of the email??
so basically
$smtp = Net::SMTP->new('smtp.blah');
$smtp->('no-replay#blah.com');
$smtp->to('$personEmail');
$smtp->data();
$smtp->datasend($locationOfOftTemplate);
$smtp->dataend();
$smtp->quit;

Answer 1

AFAIK there is no module for handling this proprietary format. Instead, translate it to a standard templating system:
my $template = <<'TEMPLATE';
Good morning, [% name %]!
Today is your first day at work. You have already received your universal login
credentials:
[% ldap_user %]
[% ldap_pass %]
It works for authenticating at the Web proxy, mail system, Jabber and internal
services. Change the password ASAP: <[% ldap_web %]>
--
Yours sincerely, the greeting daemon
TEMPLATE
use Text::Xslate qw();
my $text = Text::Xslate->new(syntax => 'TTerse')->render_string($template, {
name => 'New Bee',
ldap_user => 'nbee',
ldap_pass => 'CON-GLOM-O',
ldap_web => 'http://192.168.0.1:8080/',
});
Use a MIME toolkit to create emails. HTML/multipart/attachments are easy with
Courriel::Builder:
use Courriel::Builder;
my $email = build_email(
subject('Welcome'),
from('no-reply#example.com'),
to('…'),
plain_body($text),
);
Finally, send it using the high-level library Email::Sender that gives you nice error checking and allows you to easily switch out transports - run local delivery for testing.
use Email::Sender::Simple qw(sendmail);
use Email::Sender::Transport::SMTP qw();
use Try::Tiny;
try {
sendmail(
$email,
{
transport => Email::Sender::Transport::SMTP->new({
host => 'smtp.example.invalid',
})
}
);
} catch {
warn "sending failed: $_";
};