Generating a field not in a structs list - specman

Question

Say we have a struct which has an int field called idx.
I have a list of this struct and i need to generate an index which isn't in this list.
The most direct keep would be:
gen idx keeping {
it not in mylist.idx;
};
The problem is that if mylist is long, then mylist.idx we return a big list.
I would have prefered to do:
gen idx keeping {
not mylist.has(it.idx == it);
};
Is there any other way to do this, with better memory performance?

Answer 1

Indeed when a list.field returns a new list, and when doing it repetitively, a lot of memory can be allocated.
One way to ease the pain a little is to use an auxiliary list to avoid the use of the "mylist.idx" and an allocation of a new list.
In this way, if your original code was
<'
struct A {
idx:int;
};
extend sys {
run() is also {
var mylist: list of A;
var idx:int;
for i from 0 to 10000 {
gen idx keeping {it not in mylist.idx};
mylist.add(new A with {.idx = idx;});
};
};
};
'>
with peak process size: 969MB
you could add an auxiliary list:
<'
struct A {
idx:int;
};
extend sys {
run() is also {
var mylist: list of A;
var l : list of int;
var idx:int;
for i from 0 to 10000 {
gen idx keeping {it not in l};
mylist.add(new A with {.idx = idx;});
l.add(idx);
};
};
};
'>
with peak process size: 736MB
However, since Specman 12.2 you can use the "set" type with the auxiliary variable, which is more effective in generation.
<'
struct A {
idx:int;
};
extend sys {
run() is also {
var mylist: list of A;
var S:set;
var idx:int;
for i from 0 to 10000 {
gen idx keeping {it not in value(S)};
mylist.add(new A with {.idx = idx;});
S = S.union([idx]);
};
};
};
'>
with peak process size: 135MB