separating a string which does not has a delimiter in it - perl

Question

Can we separate a string using index values, so that my input which comprises of combined characters can be separated and the final output would be a string which is readable.
Input = 20140610182213
Expecting Output = 2014-06-10 18:22:13

Answer 1

I usually use a substitution for similar tasks:
my $input = '20140610182213';
$input =~ s/(....)(..)(..)(..)(..)(..)/$1-$2-$3 $4:$5:$6/;
print $input;
Another possibility is to use substr:
my $input = '20140610182213';
my #delims = ('-', '-', ' ', ':', ':');
substr $input, $_, 0, pop #delims for 12, 10, 8, 6, 4;
print $input;

Answer 2

You might like unpack for this:
my ( $year, $mon, $mday, $hour, $min, $sec ) = unpack "A4 A2 A2 A2 A2 A2", "20140610182213";
say "$year-$mon-$mday $hour:$min:$sec";

Answer 3

Let's get all modern on you:
use strict;
use warnings;
use feature qw(say);
my $input = "20140610182213";
$input =~ /(?<year>\d{4})
(?<month>\d{2})
(?<day>\d{2})
(?<hour>\d{2})
(?<minute>\d{2})
(?<second>\d{2})/x;
say "$+{year}-$+{month}-$+{day} $+{hour}:$+{minute}:$+{second}";
I'm using named back references here. In Perl since the very early beginning, you always had numeric back references which I could set by using parentheses:
$input =~ /(\d{4})(\d{2})(\d{2})/;
my $year = $1;
my $month = $2;
my $day = $3;
Each parentheses grouping was a back reference. This was taken directly from sed.
In Perl 5.10, named back references can now be used. They're in the format of (?<name>regex) where name is the name of the back reference and regex is the regular expression. To refer to them, you use $+{name} where name is your back reference name.
The big advantage is that you now have actual names for your back references, and you don't have to worry what $2 means:
$input =~ /(?<year>\d{4})(?<month>\d{2})(?<day>\d{2})/;
my $year = $+{year};
my $month = $+{month};
my $day = $+{day};
Now, we use the x flag in regular expressions. This allows us to have multiple line regular expressions:
$input =~ /(?<year>\d{4})
(?<month>\d{2})
(?<day>\d{2})/x; #The /x flag
my $year = $+{year};
my $month = $+{month};
my $day = $+{day};
If you're not familiar with the syntax, it can be a bit hard on the eyes at first. However, one of the nice things about this is that it documents what's going on, and makes maintenance easer. Once your eyes adjust to the light, it is easy to see what is going on and find errors.
Another possibility is to use Time::Piece to convert that date time to something that Perl can directly manipulate:
use strict;
use warnings;
use feature qw(say);
use Time::Piece;
my $input = "20140610182213";
my $date_object = Time::Piece->strptime($input, "%Y%m%d%H%M%S");
printf "%04d-%02d-%02d %02d:%02d:%02d\n",
$date_object->year,
$date_object->mon,
$date_object->mday,
$date_object->hour,
$date_object->minute,
$date_object->second;
Again, what's going on is well documented. You can see what the input string is, and you can easily refer to each part of the string, and even change the formatting. What if you want the name of the month? Use $date_object->month.
For simple parsing and never using this again, the first way is probably the best. However, by using Time::Piece, you can now check to see how days there are between two dates (for example, how old is your date/time stamp?).

Answer 4

I think this is tidiest using a global pattrn match with sprintf:
my $dt = sprintf '%s%s-%s-%s %s:%s:%s', '20140610182213' =~ /../g;
print $dt;
output
2014-06-10 18:22:13

Answer 5

If you want the values assigned to variables (e.g. $y, $m,$d etc.) for use later:
perl -E '($y,$m,$d,$H,$M,$S)="20140610182213"=~/(....)(..)(..)(..)(..)(..)/;say "$y-$m-$d $H:$M:$S"'

Answer 6

Just use Time::Piece
use strict;
use warnings;
use Time::Piece;
my $string = "20140610182213";
my $date = Time::Piece->strptime($string, "%Y%m%d%H%M%S");
print $date->strftime("%Y-%m-%d %H:%M:%S"), "\n";
Outputs:
2014-06-10 18:22:13