NetLogo selecting a value from a matrix - netlogo

Question

I have a model in which dispersing male animals challenge resident males for their territory. The dispersing male has a certain probability of winning based on his age and the age of the resident male being challenged. In other words, I ask the model to compare the age of the male agent to that of the male being challenged and then select a probability of winning. For example:
let d random-float 1
if [age] of resident-male < [age] of dispersing-male
[
set prob-winning 0.7
]
if [age] of resident-male = [age] of dispersing-male
[
set prob-winning 0.5
]
if [age] of resident-male > [age] of dispersing-male
[
set prob-winning 0.3
]
if d < prob-winning
[
ask resident-male
[
die
]
]
I have data (see below) that provides the probability of winning in a matrix with age (years) of dispersing male (3 columns) and age of resident male (13 rows).
4 5 6
3 1 1 1
4 0.5 0.55 0.65
5 0.45 0.5 0.55
6 0.4 0.45 0.5
7 0.35 0.4 0.45
8 0.4 0.45 0.5
9 0.45 0.5 0.55
10 0.5 0.55 0.6
11 0.7 0.75 0.8
12 1 1 1
13 1 1 1
14 1 1 1
15 1 1 1
It seems really inefficient to use a bunch of if statements to determine whether the male wins. Does anyone know whether there is a way to input the matrix with the probability values that I can refer to during the challenge procedure? Or any other more efficient way of selecting a specific value from a two-dimensional matrix?

Answer 1

You could always use the NetLogo array or table extensions for that, but in your case, a list of lists could also do the trick:
to-report prob-winning [ age-res age-dis ]
let probabilities [
[ 3 1 1 1 ]
[ 4 0.5 0.55 0.65 ]
[ 5 0.45 0.5 0.55 ]
[ 6 0.4 0.45 0.5 ]
[ 7 0.35 0.4 0.45 ]
[ 8 0.4 0.45 0.5 ]
[ 9 0.45 0.5 0.55 ]
[ 10 0.5 0.55 0.6 ]
[ 11 0.7 0.75 0.8 ]
[ 12 1 1 1 ]
[ 13 1 1 1 ]
[ 14 1 1 1 ]
[ 15 1 1 1 ]
]
report item (age-dis - 3) first filter [ first ? = age-res ] probabilities
end
The last line uses a combination of first and filter to find the row corresponding to the age of the resident male, and then maps the age of the displacing male (i.e., age-dis - 3) to the right "column" in the table.
You can use it like this:
let p prob-winning [age] of resident-male [age] of dispersing-male
if random-float 1.0 < p [
ask resident-male [ die ]
]
There is no validation in the code, so if you give it an age that is not part of the table, you will get an error.