enable/disable checkbox by its resident cell location - forms

Question

I want to disable/enable a checkbox in an excel sheet using vba based on the value/conditon of another checkbox. I cannot use the checkbox name, I want to use it's cell location in reference to the cell location of the checkbox that is enabling/disabling it. something like this:
Sub Software2()
Dim myRange As Range
Set myRange = Range(ActiveSheet.Shapes(Application.Caller).TopLeftCell.Address)
If ActiveSheet.Shapes(Application.Caller).ControlFormat.Value = 1 Then
myRange.Interior.ColorIndex = 35
myRange.Offset(0, 1).Interior.ColorIndex = 35
myRange.Offset(0, 2).Interior.ColorIndex = 35
myRange.Offset(1, 1).Interior.ColorIndex = 44
myRange.Offset(1, 2).Interior.ColorIndex = 44
myRange.Offset(2, 1).Interior.ColorIndex = 44
myRange.Offset(2, 2).Interior.ColorIndex = 44
Else
myRange.Interior.ColorIndex = 44
myRange.Offset(0, 1).Interior.ColorIndex = 44
myRange.Offset(0, 2).Interior.ColorIndex = 44
myRange.Offset(1, 1).Interior.ColorIndex = 0
myRange.Offset(1, 2).Interior.ColorIndex = 0
myRange.Offset(2, 1).Interior.ColorIndex = 0
myRange.Offset(2, 2).Interior.ColorIndex = 0
'ActiveSheet.Shapes(location of other checkbox).ControlFormat.Enabled = 0
'ActiveSheet.Shapes(location of other checkbox).ControlFormat.Enabled = 0
End If
End Sub

Answer 1

Here's a demo of how to find a control by its position relative to a range.
TopLeftCell is a bit finicky since the control might drift a bit to the top and/or left and so not get found. Using relative Top/Left position is a bit more robust.
You could even combine the two - depends on the relative size of the cell and the control.
Option Explicit
Sub Tester()
Dim cb
Set cb = GetControlFromRange(Range("B6"))
If Not cb Is Nothing Then
Debug.Print cb.Name
'toggle enabled
With cb.ControlFormat
.Enabled = Not .Enabled
End With
End If
End Sub
Function GetControlFromRange(rng As Range) As Object
Const POS_DELTA_MAX As Long = 10
Dim c As Object, s As Shape
For Each s In rng.Parent.Shapes
If s.Type = msoFormControl Then
'using TopLeftCell
' If Not Application.Intersect(s.TopLeftCell, rng) Is Nothing Then
' Set c = s
' Exit For
' End If
'using position
If Abs(s.Top - rng.Top) < POS_DELTA_MAX And _
Abs(s.Left - rng.Left) < POS_DELTA_MAX Then
Set c = s
Exit For
End If
End If
Next s
Set GetControlFromRange = c
End Function