perl logic request for an IO scenario - perl

Question

I need help in building a logic for below scenario.
I am using Perl to read 2 files which have 4 and 2 elements as below. I need to read each line from File1 and compare if code exists in both files.
If code exists in both files, I need to display all the line elements of file1 along with its description. Can you please share your thoughts?
File1:
Testname, code, date, file
Test1, 4, 4/11/15, /tmp
Test2, 2, 4/11/15, /log
Test3, 1, 4/11/15, /log
File2:
Code: description
1: Generic user error
2: Error with file location
3: File not found
4: Syntax error

Answer 1

Here's a working solution:
#!/usr/bin/perl
use strict;
use warnings;
use utf8;
## read file2 first
my $fh2;
open($fh2, '<', 'file2' ) || die("error: could not open file2: $!");
my $header2 = <$fh2>;
chomp($header2);
my $names2 = split(': ',$header2);
my $descriptionMap = {};
while (my $line = <$fh2>) {
chomp($line);
my $fields = [split(': ',$line)];
$descriptionMap->{$fields->[0]} = $fields->[1];
} ## end while
close($fh2);
## run through error list from file1 and print out all error info, plus description from file2 (if found)
my $fh1;
open($fh1, '<', 'file1' ) || die("error: could not open file1: $!");
my $header1 = <$fh1>;
chomp($header1);
my $names1 = [split(', ',$header1)];
while (my $line = <$fh1>) {
## parse
chomp($line);
my $fields = [split(', ',$line)];
my $error = {};
#$error{#$names1} = #$fields; ## hash slice assignment
## get description
my $description = exists($descriptionMap->{$error->{'code'}}) ? $descriptionMap->{$error->{'code'}} : '(not found)';
## output
print($error->{'Testname'},',',$error->{'code'},',',$error->{'date'},',',$error->{'file'},',',$description,"\n");
} ## end while
close($fh1);
exit 0;
Output:
Test1,4,4/11/15,/tmp,Syntax error
Test2,2,4/11/15,/log,Error with file location
Test3,1,4/11/15,/log,Generic user error
It works by first reading in file2 into a hash keyed on the code, whose value is the description. Next, it reads file1, and for each error, prints out its info, with a lookup on the file2 hash to get the description.

Answer 2

If you are using Perl to read two files, you must certainly have code to show that we could help you with. If you haven't written any code, it's not clear why you would land on one specific language as a means to the end. In the absence of code to help you work through, it's probably best to start with a description of how one might solve the problem.
You could start by reading file2 into a data container that makes it easy to do code lookups. If the code numbers are are sparsely distributed, you would probably use a hash where the keys are the code number, and the values are the codes' descriptions. If the numbers are densely distributed, you might use an array as your structure, where the index represents the code number, and the value is the code's description. Since we don't know the answer to that question, we should probably explore a general solution that would work satisfactorily in either case; a hash is advisable.
The next step would be to iterate over the lines in file1, extract the code from the line using either a regular expression, or split, or Text::CSV, and then using that code to perform the lookup in your code reference hash.
Here is a sample implementation of that strategy:
open my $f2, '<', 'file2' or die $!;
my %codes = map { m/^(\d+):\s*(.+)$/ ? ($1,$2) : () } <$f2>;
open my $f1, '<', 'file1' or die $!;
while( <$f1> ) {
next unless m/^[^,]+,\s*(\d+),/;
exists $codes{$1} && do {
chomp;
print "$_ => $codes{$1}\n";
};
}
So in the first segment of that code we open file2, and extract its lines into a hash called %codes. The keys in the hash are the numeric codes, and the values are the textual descriptions.
In the second segment we iterate over the lines of file1, again extracting the code. We use that code to do a lookup of the code's meaning. If the lookup fails to find meaning, we move on. Otherwise, we go ahead and print the line from file1 and the code's meaning from file2.
The output this produces is:
Test1, 4, 4/11/15, /tmp => Syntax error
Test2, 2, 4/11/15, /log => Error with file location
Test3, 1, 4/11/15, /log => Generic user error
It seems to me it would probably be better to print something even if the code isn't found. If that's preferable to you, you could alter that second block of code to look like this:
open my $f1, '<', 'file1' or die $!;
while( <$f1> ) {
next unless m/^[^,]+,\s*(\d+),/;
chomp;
print "$_ => ", exists $codes{$1} ? "$codes{$1}\n" : "UNKNOWN CODE\n"
}
The two snippets of code differ in that the first one will skip any lines in file1 where a matching code is not found in file2. This seems to fit the description of the goal provided in your question. The second snippet prints every line from file1 that has a code, and for those lines where a matching code isn't found from file2, the response "UNKNOWN CODE" is printed in lieu of a code description.