Define a macro variable for the quarter number - macros

Question

Part A:
Define a macro variable for the quarter number. The idea is that this is the only thing the "user" should have to change when running the program for a new quarter.
Part B:
Define macro variables for each month in the quarter and set them equal to a month value that is generated from the quarter number. Hint: %if/%then
Given code:
data Month1;
input Name $ sales;
cards;
Joyce 235
Marsha 352
Bill 491
Vernon 210
Sally 418
;
data Month2;
input Name $ sales;
cards;
Joyce 169
Marsha 281
Bill 315
Vernon 397
Sally 305
;
data Month3;
input Name $ sales;
cards;
Joyce 471
Marsha 314
Bill 394
Vernon 291
Sally 337
;
data Month4;
input Name $ sales;
cards;
Joyce 338
Marsha 259
Bill 310
Vernon 432
Sally 362
;
data Month5;
input Name $ sales;
cards;
Joyce 209
Marsha 355
Bill 302
Vernon 416
Sally 475
;
data Month6;
input Name $ sales;
cards;
Joyce 306
Marsha 472
Bill 351
Vernon 405
Sally 358
;
proc sql;
create table qtr1 as
select Month1.name, month1.sales as m1sales, month2.sales as m2sales,
month3.sales as m3sales, sum(month1.sales, month2.sales, month3.sales) as qtr1sales
from month1, month2, month3
where month1.name=month2.name=month3.name;
select sum(m1sales) as m1total, sum(m2sales) as m2total, sum(m3sales) as m3total,
sum(qtr1sales) as qtr1total
from qtr1;
My solution:
/* question a */
%MACRO qtrn(qtr);
proc print data=&qtr ;
run;
%MEND qtrn;
/* question b */
%Macro Firstqtr(qtr);
%Let I = 1;
%If &qtr = qtr1 %then %do %until (&I > 3);
%Let var&I = Month&I;
%let I = %eval(&I + 1);
%end;
%Mend Firstqtr;
%Firstqtr(qtr);
Can anyone help me figure correct solution?

Answer 1

since this looks like a homework problem, here's the main part of your answer. I'll leave the final select for you to add. Should be pretty simple given the following solution:
%macro qtrSales(qtr);
%do i = 1 %to 3;
%let month&i = month%sysevalf((&qtr-1) * 3 + &i);
%put &&month&i;
%end;
proc sql;
create table qtr&qtr as
select &month1..name,
&month1..sales as &month1.sales,
&month2..sales as &month2.sales,
&month3..sales as &month3.sales,
sum(&month1..sales, &month2..sales, &month3..sales) as qtr&qtr.sales
from &month1, &month2, &month3
where &month1..name=&month2..name=&month3..name;
select sum(&month1.sales) as &month1.total,
sum(&month2.sales) as &month2.total,
sum(&month3.sales) as &month3.total,
sum(qtr&qtr.sales) as qtr&qtr.total
from qtr&qtr;
select sum(&month1.sales) as &month1.total,
sum(&month2.sales) as &month2.total,
sum(&month3.sales) as &month3.total,
sum(qtr&qtr.sales) as qtr&qtr.total
from qtr&qtr;
quit;
%mend qtrSales;
%qtrSales(2);

Answer 2

define a macro variable means simply to use %let to define a macro variable. macro variables are things that you define with %let, call symputx, or select into in SQL, and then reference using &.
%let qtrn = 3;
There you go. The question specified that the user will adjust this, right? So it isn't asking you to do any work on your end, just give the user a place to make this change.
As for the second, I don't entirely understand the hint. It doesn't seem necessary to use conditional logic here. Here's an example of what I'd do.
%let month1 = %eval(3*(&qtrn.-1)+1);
That simply calculates the month number of the first month based on the quarter. Quarter 3 is months 7/8/9, right? 3*(3-1)+1 = 7, 3*(3-1)+2 = 8, 3*(3-1)+2 = 9. (Or you could do it differently, 3*3-2 = 7, 3*3-1 = 8, 3*3 = 9)
Of course, you could do this in a macro with a loop to define them. But it seems excessive to do so - it's not like quarters ever have 4 months in them, or 2, right? They always have 3, it's a defining characteristic of a quarter, so it seems fine to hardcode month1/month2/month3.