Parsing timestamp string to integer and subtract hires timestamp - perl

Question

New to perl. I have a string that is in this form 20190123120445, i.e. YYYYMMDDHHMISS. In perl how do you turn this into a timestamp that can be used to subtract another timestamp generated from a Time::Hires time timestamp. I know the timestamps are different resolutions and will assume that the first timestamp starts at 0 ms.
I can turn the timestamp into a DateTime object, however attempting to subtract the hires timer value result in error.
How do I turn the first string into a timestamp of the same resolution as the time timestamp, so that I can subtract the values and get a delta? Or is there a more obvious solution?
use Time::Hires;
use Date::Parse;
my $parser = DateTime::Format::Strptime->new(
pattern => '%Y%m%d%H%M%S',
on_error => 'croak',
);
my $dt = $parser->parse_datetime($args->{EVENTCREATEDTIMESTAMP});
my $delta = time - $dt;
If I attempt to do this, I get this error
Bad message vendor or subscription: Cannot subtract 1548265276 from a
DateTime object (DateTime=HASH(0x28e10d98)). Only a DateTime::Duration
or DateTime object can be subtracted from a DateTime object.

Answer 1

To submit it as a proper answer: To get an epoch timestamp which is the same format you get from time, call the epoch method on the DateTime object. You can easily subtract epoch timestamps to get a difference in seconds, and then convert that to larger denominations. Time::Seconds provides useful constants for this if you prefer.
use strict;
use warnings;
use Time::Seconds;
my $diff = time - $dt->epoch;
my $diff_hours = $diff / ONE_HOUR;
If you want a calendar duration difference, things get complicated. This is because there is no static definition of things like "one month" or even "one day" and "one minute", because of gross things like daylight savings and leap seconds. So the difference depends on the time zone and the absolute start and end time. The simplest way to deal with this is turn your epoch timestamp into a DateTime object and have DateTime do the work for you.
my $dt_time = DateTime->from_epoch(epoch => time);
# Each of the following returns DateTime::Duration objects with different measures of calendar time
my $diff_duration = $dt_time->subtract_datetime($dt); # months, days, minutes, seconds, nanoseconds
my $diff_days = $dt_time->delta_days($dt); # full days
my $diff_ms = $dt_time->delta_ms($dt); # minutes and seconds
my $diff_abs = $dt_time->subtract_datetime_absolute($dt); # seconds and nanoseconds
The individual components of the resulting DateTime::Duration objects can be retrieved with the in_units method or by passing it to DateTime::Format::Duration. The subtract_datetime_absolute method is the only way to count leap seconds - epoch timestamps effectively ignore them, and "minutes" from the other methods may not be 60 seconds long.