Adding attributes to items of a list - netlogo

Question

I would like to know how to add attributes for each element of a list.
In particular, I have a list made by adding items at each tick. Each item has two attributes. These attributes are important to me, as I want to select an item based on the value of its attribute.
I did something like this:
ask one-of turtles ;; turtles have cars
[ set attribute_1 ;; cars' attribute
set attribute_2 ;; cars' attribute
set mylist fput car mylist
]
I would like something like this [car1 attribute_1 attribute_2, car2 attribute_1 attribute_2, car3...].
At the moment I have [car1 car2 car3...].
Once associated the attributes to the items, I would need to pick the item with highest value from the list. The user Omarito provided me a possible solution: How to select the item with highest value in a list, but it is not completely clear to me how to pick an item up.
What I would like to ask you is if it is possible to have something like [car1 attribute_1 attribute_2, car2 attribute_1 attribute_2, car3...] or if I can only have something like
[car1 car2 car3...]
or
[[attribute_1 attribute_2] [attribute_1 attribute_2] ...].
If I write set mylist fput [(list attribute_1 attribute_2)], I receive the error message: expected a literal value.
I hope you can help me. Thanks
UPDATE: After Nicolas' answer, I edited the code as follows:
ask one-of turtles
[
hatch-cars 1[ ;; buy a new car
set attribute_1 random-float 1
set attribute_2 random-float 1
]
let this-car self
set my-list fput this-car my-list
; ask turtles [show my-list]
set new_car? true
set old_car? false
set new_car new_car + 1 ;; how could I update it after the change?
]
Am I missing something?

Answer 1

There are many ways to approach this problem, but I will just give you two.
Let's start with the one closest to the way you're currently trying to do things.
turtles-own [ my-list ]
to setup
clear-all
create-turtles 3 [
set my-list [] ; start with empty list
foreach range 5 [ car -> ; let's pretend cars are just numbers
let attribute-1 precision (random-float 1) 2
let attribute-2 precision (random-float 1) 2
set my-list fput (list car attribute-1 attribute-2) my-list
]
]
ask turtles [
show my-list
print " Best car by attribute 1:"
let best-by-1 last sort-by [ [a b] -> item 1 a < item 1 b ] my-list
print word " Sublist: " best-by-1
print word " Car number: " item 0 best-by-1
print " Best car by attribute 2:"
let best-by-2 last sort-by [ [a b] -> item 2 a < item 2 b ] my-list
print word " Sublist: " best-by-2
print word " Car number: " item 0 best-by-2
print "--------"
]
end
Most of this code is for creating the turtles and displaying the result, but the two key lines are:
set my-list fput (list car attribute-1 attribute-2) my-list
for adding sublists to the main list, and:
let best-by-1 last sort-by [ [a b] -> item 1 a < item 1 b ] my-list
for sorting the main list by a specific attribute taken from the sublist. You can then use item 0 best-by-1 to get the car itself.
That being said, if you want to use NetLogo to its full potential, you should probably create a car breed:
breed [ cars car ]
cars-own [
attribute-1
attribute-2
]
breed [ agents an-agent ]
agents-own [ my-list ]
to setup
clear-all
create-agents 3 [
set my-list [] ; start with empty list
hatch-cars 5 [
set attribute-1 precision (random-float 1) 2
set attribute-2 precision (random-float 1) 2
let this-car self
ask myself [ set my-list fput this-car my-list ]
]
]
ask agents [
show my-list
print " Best car by attribute 1:"
let best-by-1 max-one-of turtle-set my-list [ attribute-1 ]
print (word " " best-by-1 ", attribute-1 = " [ attribute-1 ] of best-by-1)
print " Best car by attribute 2:"
let best-by-2 max-one-of turtle-set my-list [ attribute-2 ]
print (word " " best-by-2 ", attribute-1 = " [ attribute-2 ] of best-by-2)
]
end
The max-one-of primitive makes it easy to pick the best car and everything else will also probably be easier if you're working with agents instead of lists.