Deactivate a rule flow group in drools - drools

Question

I have a drl file which has rules inside 2 ruleflow-groups: "first-ruleflow-group" and "second-ruleflow-group" . The activation of these groups depend on "rule A" and "rule B". Is there any way in which I can deactivate rule B to fire when rule A condition matches, so that the focus is set only to "first-ruleflow-group"?
rule "rule A"
when
eval(true);
then
drools.setFocus("first-ruleflow-group");
end
rule "rule B"
when
eval(true);
then
drools.setFocus("second-ruleflow-group");
end

Answer 1

Change your rules rely on exclusive conditions.
Simple example. Let's say we have an application dealing with calendar events. We have a rule flow for public holidays. We have a rule flow for religious holidays. There are some religious holidays which are also public holidays; for these we only want to fire the public holiday rules.
rule "Public Holidays"
when
Holiday( isPublic == true )
then
drools.setFocus("publicholiday-flow");
end
rule "Religious Holidays"
when
Holiday( isReligious == true,
isPublic == false )
then
drools.setFocus("religiousholiday-flow");
end
So, basically, modify your "rule B" to include a condition that negates the rule A condition, so that if Rule A matches, Rule B necessarily does not.
A second solution would be to have a rule in your first rule flow (triggered by A) set a condition such that rule B doesn't trigger. It's basically similar to the previous solution except that the condition keeping Rule B from triggering is dynamic.
As an example, imagine an application that determines how much someone owes for parking. Parking rates are set by day -- there's one rate for Monday through Friday, a rate for Saturday, and Sundays are free. In addition, there are other discounts applied -- for example senior citizens, or if the total amount time parked is less than 5 minutes. The day-of-the-week rates are determined using the first rule flow (A), and the discounts are determined using the second rule flow (B). If it is Sunday, there's no reason to fire the second set of rules.
You could either write the discount rule flow trigger to explicitly not fire for Sundays, or you could have the Sunday rate rule retract or insert data such that it makes the discount rules no longer valid for running.
rule "Day Rates"
when
then
drools.setFocus("dayrates-flow");
end
rule "Discounts"
when
exists(Rate( hourly > 0 ))
then
drools.setFocus("discounts-flow");
end
// The Sunday rule, part of the dayrates-flow, sets hourly = 0, which makes
// the "Discounts" rule no longer valid to fire.
rule "Sunday Rate"
ruleflow-group "dayrates-flow"
when
not(Rate())
Request( day == DayOfWeek.SUNDAY ) // when parking on Sunday...
then
Rate rate = new Rate();
rate.setHourlyRate(0.0);
insert(rate);
end
Yet another option would be to trigger the second rule flow from within the first rule flow, but only as needed.
Reusing the previous example with parking:
rule "Day Rates"
when
then
drools.setFocus("dayrates-flow");
end
// Here are some day rate rules. Most are omitted for brevity. We include three (3)
// to show regular rates, the special case of Sunday, and how we trigger the discount
// rate rules
rule "Saturday Rate"
ruleflow-group "dayrates-flow"
when
not(Rate())
Request( day == DayOfWeek.SATURDAY )
then
Rate rate = new Rate();
rate.setHourly(1.0); // Saturday rate: $1/hr
insert(rate);
end
rule "Sunday Rate"
ruleflow-group "dayrates-flow"
when
not(Rate())
Request( day == DayOfWeek.SUNDAY )
then
Rate rate = new Rate();
rate.setHourlyRate(0.0); // Sunday rate: free
insert(rate);
end
// This rule only triggers the next rule flow when the rate is positive (eg not Sunday)
rule "Transition to Discounts"
ruleflow-group "dayrates-flow"
when
exists(Rate( hourly > 0 ))
then
drools.setFocus("discount-flow");
end