Button opens Form - forms

Question

My Problem is that I Wanted to create new Forms and Buttons with procedure Button1Click(Sender: TObject);. I had the problem that i did not know how to open the new created Forms with procedure TForm2.myClick(Sender: TObject);. I wanted that different forms are created by different buttons.
unit Unit1;
interface
uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
Vcl.Controls, Vcl.Forms, Vcl.Dialogs,Vcl.StdCtrls;
type
TForm2 = class(TForm)
Button1: TButton;
procedure Button1Click(Sender: TObject);
private
{ Private-Deklarationen }
public
{ Public-Deklarationen }
procedure myClick(Sender: TObject);
end;
var
Form2: TForm2;
var
i:Integer = 1;
var
a:Integer = 1;
implementation
{$R *.dfm}
procedure TForm2.Button1Click(Sender: TObject);
begin
with TButton.Create(self) do begin
Left := 80;
Top := 50 + i * 60;
Width := 300;
Height := 50;
Name := 'Liste' + IntToStr(i);
Self.Caption := ClassName+' '+ IntToStr(i);
OnClick := MyClick;
Parent :=Form2;
end;
i:= i + 1;
begin
with TForm.Create(Self) do begin
Left := 0;
Top := 0;
Width := 1000;
Height := 700;
Name := 'Erinnerung' + IntToStr(a);
Caption := 'Erinnerung' + IntToStr(a);
Parent := self;
OnClick:= MyClick;
Visible:=false;
end;
a:= a + 1;
end;
end;
procedure TForm2.myClick(Sender: TObject);
begin
end;
end.

Answer 1

There are a few number of unspecified items in your problem. Anyway, I made a simple example of what can be done. You'll get started and modify this code to suit your needs.
This code has a form (TForm1) with a single button. Each time the user click on the button, a new button and a new form are created. The created button is show on TForm1 in a column like you have done. The form is created but not visible like you have done. A list keep reference to the buttons and forms created.
The created button and form have their Tag property set to the index in the list. The button's OnClick event handler use this index to retrieve the corresponding form from the list and make it visible.
The form is created with a nil Parent so that it is a flying window. If you use Self instead of nil, the created form will be inside TForm1, much like an MDI application.
Here is the code:
unit DynFormDemoMain;
interface
uses
Winapi.Windows, Winapi.Messages,
System.SysUtils, System.Variants, System.Classes,
Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls,
System.Generics.Collections;
type
TFormItem = record
AForm : TForm;
AButton : TButton;
end;
TForm1 = class(TForm)
Button1: TButton;
procedure Button1Click(Sender: TObject);
private
FList : TList<TFormItem>;
procedure MyClick(Sender : TObject);
public
constructor Create(AOwner : TComponent); override;
destructor Destroy; override;
end;
var
Form1: TForm1;
implementation
{$R *.dfm}
procedure TForm1.Button1Click(Sender: TObject);
var
Item : TFormItem;
AButton : TButton;
AForm : TForm;
begin
AButton := TButton.Create(Self);
AButton.Tag := FList.Count;
AButton.Left := 80;
AButton.Top := 50 + AButton.Tag * 60;
AButton.Width := 300;
AButton.Height := 50;
AButton.Name := 'Liste' + IntToStr(AButton.Tag);
AButton.Caption := ClassName + ' ' + IntToStr(AButton.Tag);
AButton.OnClick := MyClick;
AButton.Parent := Self;
AForm := TForm.Create(Self);
AForm.Tag := AButton.Tag;
AForm.Left := AButton.Tag * 20;
AForm.Top := AButton.Tag * 20;
AForm.Width := 200;
AForm.Height := 100;
AForm.Name := 'Erinnerung' + IntToStr(AButton.Tag);
AForm.Caption := 'Erinnerung' + IntToStr(AButton.Tag);
AForm.Parent := nil;
AForm.Visible := FALSE;
Item.AForm := AForm;
Item.AButton := AButton;
FList.Add(Item);
end;
constructor TForm1.Create(AOwner: TComponent);
begin
inherited;
FList := TList<TFormItem>.Create;
end;
destructor TForm1.Destroy;
begin
FreeAndNil(FList);
inherited;
end;
procedure TForm1.MyClick(Sender: TObject);
var
Item : TFormItem;
begin
Item := FList[(Sender as TButton).Tag];
if Assigned(Item.AForm) then
Item.AForm.Show;
end;
end.