extract data from excel files and structure them into hashes - perl

Question

I have a three columns Excel file,which has the following pattern
12 A P1
23 B P5
24 C P2
15 D P1
06 E P5
The structure underlying this data set is that,
P1 contains A and D; A corresponds to 12 and D corresponds to 15
P2 contains C; C corresponds to 24
P5 contains B and E; B corresponds to 23 and E corresponds to 06
I want to represent this kind of structure in a hashed structure i.e., use P1 as a key to point to a hash, and A is used as the key for this second level hash. Is there a way to implement this in Perl?

Answer 1

Spreadsheet::ParseExcel can be used to parse .xls files. Below is a sample program that builds the desired data structure.
#!/usr/bin/env perl
use strict;
use warnings;
use Data::Dumper;
use Spreadsheet::ParseExcel;
my $parser = Spreadsheet::ParseExcel->new;
my $workbook = $parser->parse( shift or die "Please provide a file\n" );
my $worksheet = $workbook->worksheet(0);
my %data;
for my $row ( 0 .. $worksheet->row_range ) {
my $value = $worksheet->get_cell( $row, 0 )->value;
my $key = $worksheet->get_cell( $row, 1 )->value;
my $super_key = $worksheet->get_cell( $row, 2 )->value;
$data{$super_key}->{$key} = $value;
}
print Dumper \%data;
Output
$VAR1 = {
'P5' => {
'E' => '06',
'B' => '23'
},
'P2' => {
'C' => '24'
},
'P1' => {
'A' => '12',
'D' => '15'
}
};

Answer 2

I had to process data in spreadsheets in the past. If you are dealing with a small number of Excel files, export them manually to CSV files using a spreadsheet software such as Excel. Then parse the CSV file, and store the cell values in a hash of hashes in perl:
#!/usr/bin/env perl
use warnings;
use strict;
use Data::Dumper::Simple;
my $file = "";
my #row = ();
my $rowidx = 1;
my %hh = (); # hash of hashes
open( INFILE, "input.csv" ) or die("Can not open input file: $!");
while ( $file = <INFILE> ) {
#row = parse($file);
chomp(#row);
$hh{ $row[2] }{ $row[1] } = $row[0];
#warn Dumper %hh; # debug
$rowidx++;
}
close(INFILE);
warn Dumper %hh;
exit;
sub parse {
my #newrow = ();
my $columns = shift; # read next row
push( #newrow, $+ ) while $columns =~ m{"([^\"\\]*(?:\\.[^\"\\]*)*)",?|([^,]+),?|,}gx; # parse and store columns to array
push( #newrow, undef ) if substr( $columns, -1, 1 ) eq ',';
return #newrow;
}
Running this gives
$ more input.csv
12,A,P1
23,B,P5
24,C,P2
15,D,P1
06,E,P5
$ ./ReadCSV.pl input.csv
%hh = (
'P5' => {
'E' => '06',
'B' => '23'
},
'P2' => {
'C' => '24'
},
'P1' => {
'A' => '12',
'D' => '15'
}
);

Answer 3

There's the Spreadsheet::ParseExcel function which does a pretty good job of parsing a regular *.xls spreadsheet.
Fortunately, there's an extension called Spreadsheet::XLSX that works with Spreadsheet::ParseExcel to also read *.xlsx spreadsheets too. The methods used in Spreadsheet::ParseExcel work with both *.xls and *.xlsx files if you also have Spreadsheet::XLSX also installed.

Answer 4

What version of excel are the files formatted in?
I have had a very good experience with reading from (and writing to) .xls files using the modules Spreadsheet::ParseExcel (Spreadsheet::WriteExcel for output)
Unfortunately, I did this 4 years ago and the .xlsx format was not as prevalent, so I can't speak for those.