Org Mode. Sorting in column view - emacs

Question

How do we sort in a column view. In specific, I have a list of estimated taks, along with their priority, I want to be able to sort them based on any field, dynamically or atleast by specifying a field as a property.

Answer 1

AFAIK, you can't sort while you are in column view. But you exit column view (by typing "q"). They you can sort the entries by property with M-x org-sort (C-c ^). Type r for property and then enter the property you want to sort by.
E.g., let's say we begin with this:
* Test
** First task
:PROPERTIES:
:Effort: 1:30
:END:
** Second task
:PROPERTIES:
:Effort: 0:30
:END:
Navigate to "* Test" and type C-c ^ (or M-x org-sort). In this case, type "r" and then enter "Effort" to get the resulting order:
* Test
** Second task
:PROPERTIES:
:Effort: 0:30
:END:
** First task
:PROPERTIES:
:Effort: 1:30
:END:
Then enter column view again. (Note, you can also sort by priority --- you'll see the option when you invoke org-sort.)
Additionally, you can export your column view to a table and then sort the table by column:
http://orgmode.org/manual/Capturing-column-view.html

Answer 2

Wanting to sort in column view quite often, I wrote a command which does it by exiting column view, sorting, and then reentering column view:
(defun org-columns-sort (&optional arg)
"Sort entries from column view by value in current column.
This only sorts the children of the column view top level,
which is the entry with the current column view specification.
When ARG is non-nil (interactively with prefix), sort in
reverse order."
(interactive "P")
(let ((colname (get-char-property (point) 'org-columns-key))
(colnum (org-current-text-column)))
(org-columns-goto-top-level)
(org-columns-quit)
(org-sort-entries nil (if arg ?R ?r) nil nil colname)
(org-columns)
(outline-hide-sublevels
(1+ (org-current-level)))
(forward-char colnum)))
(org-defkey org-columns-map "^" #'org-columns-sort)
Or, if you want an alternative keybinding:
(defun org-columns-sort-reverse ()
"Calls `org-columns-sort' with non-nil argument."
(interactive)
(org-columns-sort t))
(org-defkey org-columns-map [(meta down)] #'org-columns-sort)
(org-defkey org-columns-map [(meta up)] #'org-columns-sort-reverse)
Suggestions for improvement are welcome. It doesn't quite restore the original folding and position. I tried storing (point-marker) and then use goto-char but somehow the marker gets lost.
Example: custom sort order
To get a nicer sort order for columns containing numbers or a mix of non-number strings and numbers, replace (org-sort-entries nil (if arg ?R ?r) nil nil colname) above with
(org-sort-entries nil (if arg ?F ?f)
(lambda () (org-entry-get nil colname))
#'my-org-columns-sort-function)
with
(defconst my-string-number-regex
(concat "^[+-]?\\(?:[0-9]+\\(?:[.,][0-9]*\\)?\\(?:e[+-]?[0-9]+\\)?"
"\\|[.,][0-9]+\\(?:e[+-]?[0-9]+\\)?\\)$")
"Matches integers and floats with exponent.
This allows for leading and trailing decimal point, leading zeros in base,
leading zeros in exponent, + signs, and , as alternative decimal separator.")
(defun my-org-columns-sort-function (x y)
"Returns non-nil if X should sort before Y (is less than Y).
This function gives a nice sort order when used with `org-columns-sort'.
Both arguments can be either a cons, a non-number string, or a
number-string. Across types the sort order is as mentioned.
Within types, `string-lessp` is used for non-number strings,
and `<` is used for number-strings."
(cond
((and (consp x)(consp y))
nil)
((and (consp x)(not (consp y)))
t)
((and (not (consp x))(consp y))
nil)
(t
(let ((sxp (not (string-match-p my-string-number-regex x)))
(syp (not (string-match-p my-string-number-regex y))))
(cond
((and sxp syp)
(string-lessp x y))
((and sxp (not syp))
t)
((and (not sxp) syp)
nil)
(t
(< (string-to-number x) (string-to-number y))))))))
See here if you want a less general pattern for matching numbers.