Classic ASP arraylist attribute in class? - class

Question

How can I add an arraylist attribute into a class using classic ASP?
My Example (Not working):
Class AA
Public AA_id
Dim data: set data = CreateObject("System.Collections.ArrayList")
End Class

Answer 1

You need to initialize class members inside a method - function, sub routine of the class constructor. Naturally, the best of these is inside the constructor.
Fully working code demonstrating how to use the .NET ArrayList as part of custom VBScript class:
<%
Class MyCustomClass
Private internalArrayList
Private Sub Class_Initialize()
Set internalArrayList = Server.CreateObject("System.Collections.ArrayList")
End Sub
Private Sub Class_Terminate()
Set internalArrayList = Nothing
End Sub
Public Sub AddItem(oItem)
internalArrayList.Add(oItem)
End Sub
Public Function ToString()
Dim data, x
data = "List contains " & internalArrayList.Count & " item"
If internalArrayList.Count<>1 Then data = data & "s"
For x=0 To internalArrayList.Count-1
data = data & "<br />"
If IsObject(internalArrayList(x)) Then
data = data & "complex object of type " & TypeName(internalArrayList(x))
ElseIf IsArray(internalArrayList(x)) Then
data = data & "array with " & (UBound(internalArrayList(x)) + 1) & " items"
Else
data = data & internalArrayList(x)
End If
Next
ToString = data
End Function
End Class
%>
Usage sample, including adding a complex object:
Class Foo
Public Dummy
End Class
Dim myInstance, myFoo
Set myInstance = New MyCustomClass
myInstance.AddItem("hello")
myInstance.AddItem("world")
myInstance.AddItem(Array(1, 2, 3))
Set myFoo = New Foo
myFoo.Dummy = "just checking"
myInstance.AddItem(myFoo)
Response.Write(myInstance.ToString())