Awk: merge orphaned text to specific field in line above - sed

Question

Given a tab-delimited text file containing item information:
41850 0.4 0.5 LG EN RP Billy Makes a Fridgewell, Norm
Friend
9338 0.4 0.5 LG EN RP Shine, The Musical! Mustard, Colonel
7255 0.5 0.5 LG EN RP Can You Play the Truman, Harriet
Jew's Harp
9314 0.5 0.5 LG EN RP Hi, Skippy Plum, Prof
Note the "orphaned" titles on two of the lines. Using Awk, how can I merge this orphan back into the title field above?
Pseudo-awk:
awk '/^[[:digit:]]/{getline; ???
if next line ~ /^[[:alpha:]]/ title=$7 + previous
END{print $0}' <FILE
Anyway the steps seem to be:
Either
Find "normal" lines,
Test if following line is "orphan"
if so, append "orphan" to field 7 [ title field ],
Print line
or
Find "orphans"
Somehow append to field 7 of previous line [ there will never be two consecutive orphans ]
The first way seems easiest to me --- but then, I'm the one in ignorance here.

Answer 1

This might work for you (GNU sed):
sed '$!N;/\n\([^\t]*\t\)\{7\}/!s/\(\t[^\t]*\)\n\(.*\)/ \2\1/;P;D' file

Answer 2

$ tac file | awk 'BEGIN{FS=OFS="\t"} NF==1{s=" "$0;next} {$7=$7 s; s=""}1' | tac
41850 0.4 0.5 LG EN RP Billy Makes a Friend Fridgewell, Norm
9338 0.4 0.5 LG EN RP Shine, The Musical! Mustard, Colonel
7255 0.5 0.5 LG EN RP Can You Play the Jew's Harp Truman, Harriet
9314 0.5 0.5 LG EN RP Hi, Skippy Plum, Prof
Here's an alternative approach without tac and using GNU awk (just replace gensub() with 2 sub() calls or match() or whatever if you don't want to use gawk):
$ cat tst.awk
BEGIN { FS="\t" }
NF==1 { s = gensub(/([^\t]+[\t]){6}[^\t]+/, "\\0 "$1, "", s); next }
{ printf "%s",s; s=$0 ORS }
END { printf "%s",s }
$ gawk -f tst.awk file
41850 0.4 0.5 LG EN RP Billy Makes a Friend Fridgewell, Norm
9338 0.4 0.5 LG EN RP Shine, The Musical! Mustard, Colonel
7255 0.5 0.5 LG EN RP Can You Play the Jew's Harp Truman, Harriet
9314 0.5 0.5 LG EN RP Hi, Skippy Plum, Prof

Answer 3

I realize the question is tagged awk, but this might be one of those times when it's easier with Perl:
perl -F"\t" -lane 'BEGIN { $, = "\t" }
if (/^\d{2}/) { print #saved if #saved; #saved = #F }
else { $saved[6].=" $_" };
END { print #saved }' foo.txt
Though here's an awk version of the same idea (with some improvements via Ed Morton):
awk -F"\t" '/^[0-9][0-9]/ { if (prefix) { print prefix"\t"title"\t"suffix }
prefix=$1
for ( i=2; i<=6; ++i ) prefix=prefix"\t"$i
title=$7; suffix=$8
next }
{ title = title" "$0 }
END { print prefix"\t"title"\t"suffix }' foo.txt
Both scripts give me this output, which looks like what you want:
41850 0.4 0.5 LG EN RP Billy Makes a Friend Fridgewell, Norm
9338 0.4 0.5 LG EN RP Shine, The Musical! Mustard, Colonel
7255 0.5 0.5 LG EN RP Can You Play the Jew's Harp Truman, Harriet
9314 0.5 0.5 LG EN RP Hi, Skippy Plum, Prof