Code in Perl for pi calculation - perl

Question

Could someone explain step by step this code in Perl:
$.=.5;
$\=2/$.++-$\for$...1e6;
print

Answer 1

Add white space:
$. = .5;
$\ = (2 / $.++) - $\ for $. .. 1e6;
Substitute with saner var names:
$x = .5;
$pi = (2 / $x++) - $pi for $x .. 1e6;
Don't use the same var for two purposes:
$x = .5;
$pi = (2 / $x++) - $pi for 0 .. 1e6;
Convert to formula:
pi = 2/1000000.5 - ( ... - (2/2.5 - (2/1.5 - (2/0.5))))
= 2/1000000.5 - ... + 2/2.5 - 2/1.5 + 2/0.5
= 4/2000001 - ... + 4/5 - 4/3 + 4/1
= 4/1 - 4/3 + 4/5 - ... + 4/2000001
which is listed in Wikipedia as the Gregory–Leibniz series.
print; is print($_);, which prints $_ (unused, so undef, which stringifies to empty string) followed by $\ (which is normally an empty string, but is used as the accumulator in the original code).

Answer 2

Let's start first by breaking the code down into something more readable with some white-space. White space is relatively unimportant in Perl.
$. = .5;
$\ = 2 / $.++ - $\ for $. .. 1e6;
print
This code is making use of Perl's special built-in global variables to make things look short (man perlvar for more details on the specific variables this code is using). Let's make it more readable by replacing them with names that are human readable.
$denominator = .5;
$pi = 2 / $denominator++ - $pi for $denominator .. 1e6
print $pi
And just to help, let's move the inline for loop into a more verbose loop.
$denominator = .5;
foreach my $i ($denominator .. 1e6) {
$pi = 2 / $denominator - $pi;
$denominator += 1;
}
print $pi
So, this makes it a bit easier to decipher, and it's a standard convergence routine for calculating pi. There's a number of different ones, but basically, if you step through it, you'll see that it converges to the famous 3.14159... The denominator is okay to use as the first element of the sequence generator because it will floor to the integer 0.
Pass 1: 2 / 0.5 - 0 = 4
Pass 2: 2 / 1.5 - 4 = -2.666...
Pass 3: 2 / 2.5 - (-2.666...) = 3.4666...
Pass 4: 2 / 3.5 - 3.4666... = -2.895...
Pass 5: 2 / 4.5 - (-2.895...) = 3.339...
You get the idea. The code runs through 1,000,001 passes to reach the final approximation. As long as it runs an odd number of approximations, it should converge to pi (even numbered approximations converge to negative pi).
The reason the print statement works is that $\ is the output record separator. print by itself will print $_, the default variable, which will be empty. The value of pi will be in the $\ value, which will effectively be the line ending, so it prints out a blank value followed by the calculated value of pi (no traditional line ending).

Answer 3

Wow, that's a beauty. Someone was trying to make that look as convoluted as possible. Here's a more readable version:
my $pi = 0;
for (my $i=0.5; $i < 1e6+1; $i++)
{
$pi=2/$i - $pi;
}
print $pi."\n";
This is the mathematical representation of the Gregory-Leibnitz Formula
The original version uses a few Perl special variables to confuse you. The $. is entirely unnecessary here and purely for obfuscation. The $\ is the output record separator. That means this variable will be appended after a print statement. Therefore, the single print at the end simply prints the result of the calculation that was stored in $\. Finally, the code uses a post-fix for loop and the .. operator instead of the more explicit for loop in my version. I hope that clears things up a bit.

Answer 4

This can be rewritten as:
use strict;
use warnings;
my $divisor = 0.5;
my $pi = 0;
for my $i (0..1e6)
{
$pi = 2 / $divisor++ - $pi
}
print "$pi\n";
So it uses some mathematical series expansion to calculate pi (See #ikegami's answer)