How to make zsh vi-style commands respect WORDCHARS? - command-line

Question

I prefer vi-style word movements such as vi-forward-word instead of forward-word, so that the cursor also stops on separator characters. However, I would also like to make zsh respect WORDCHARS in this case or somehow define my separator characters. Is this possible somehow? It seems I can either make zsh use my separator characters, or use vi-style movements where it also stops on them, but not both.
So e.g. if my line is the following:
% ls -la /foo/bar/f-b/r
then if I start moving forward word by word, it will stop on /, foo, /, bar, /, f-b, /, r.
Relevant lines from my .zshrc:
WORDCHARS='*?_-.[]~=&;!#$%^(){}<>' # removed /
autoload select-word-style
select-word-style normal
bindkey '^W' vi-backward-kill-word
bindkey '^f' vi-forward-word
bindkey '^b' vi-backward-word

Answer 1

In the end I just implemented my own zle widgets:
SEPCHARS='[/ ]'
my-forward-word() {
if [[ "${BUFFER[CURSOR + 1]}" =~ "${SEPCHARS}" ]]; then
(( CURSOR += 1 ))
return
fi
while [[ CURSOR -lt "${#BUFFER}" && ! "${BUFFER[CURSOR + 1]}" =~ "${SEPCHARS}" ]]; do
(( CURSOR += 1 ))
done
}
zle -N my-forward-word
bindkey '^f' my-forward-word
my-backward-word() {
if [[ "${BUFFER[CURSOR]}" =~ "${SEPCHARS}" ]]; then
(( CURSOR -= 1 ))
return
fi
while [[ CURSOR -gt 0 && ! "${BUFFER[CURSOR]}" =~ "${SEPCHARS}" ]]; do
(( CURSOR -= 1 ))
done
}
zle -N my-backward-word
bindkey '^b' my-backward-word
my-backward-kill-word() {
if [[ "${LBUFFER[CURSOR]}" =~ "${SEPCHARS}" ]]; then
LBUFFER="${LBUFFER[1, CURSOR - 1]}"
return
fi
while [[ CURSOR -gt 0 && ! "${LBUFFER[CURSOR]}" =~ "${SEPCHARS}" ]]; do
LBUFFER="${LBUFFER[1, CURSOR - 1]}"
done
}
zle -N my-backward-kill-word
bindkey '^W' my-backward-kill-word