grep / sed: How to print *something* when nothing matches - sed

Question

thanks for reading.
I have a plain text file with some simple user information
The thing is, sometimes one of those items is missing.
Notice how Norman and Reggie show an email addr, but Missy doesn't:
Name: Norman Normalrecord
Email: norman#ooga.com
Addr: 123 Main street
Name: Missy Missington
Addr: 789 Back street
Name: Reggie Regularrecord
Email: reggie#booga.com
Addr: 456 Middle street
I would like to grep / sed and say "If no email address is found, substitute with the text missing_email_addr", so I get this result :
Norman Normalrecord
norman#ooga.com
123 main street
Missy Missington
MISSING_EMAIL_ADDR
789 back street
Reggie Regularrecord
reggie#booga.com
456 middle street
The problem is, in all my experiments when nothing is found grep / sed produce absolutely nothing, so I can't even do a second pass to global-replace.
What I dream of is something like (obviously pseudo-grep) that provides what to print when a search doesn't find anything :
grep /Name:/MISSING_NAME/email:/MISSING_EMAIL_ADDR/Addr:/MISSING_STREET_ADDR/
Is there any way to do something like this? Thanks again.

Answer 1

Here's a start. It replaces missing e-mail lines with "Email: N/A".
awk -v RS='\n\n' -v FS='\n' -v OFS='\n' \
'{ if (!$3) $3 = "Email: N/A"; print; print "" }' users.txt
Output:
Name: Norman Normalrecord
Email: norman#ooga.com
Addr: 123 Main street
Name: Missy Missington
Addr: 789 Back street
Email: N/A
Name: Reggie Regularrecord
Email: reggie#booga.com
Addr: 456 Middle street

Answer 2

This might work for you (GNU sed):
sed '/^Name: /!b;:a;$!N;/\nAddr: /!ba;/\nEmail: /!s/\n/&Email: MISSING_EMAIL_ADDR&/' file
If you want to remove the labels:
sed -r '/^Name: /!b;:a;$!N;/\nAddr: /!ba;/\nEmail: /!s/\n/&Email: MISSING_EMAIL_ADDR&/;s/(Name|Email|Addr): //g' file

Answer 3

Using GNU awk for gensub():
$ cat tst.awk
BEGIN { RS=""; ORS="\n\n"; FS=OFS="\n" }
NF<3 { $3=$2; $2="Email: MISSING_EMAIL_ADDR" }
{ print gensub(/(^|\n)[^:]+:[[:space:]]*/,"\\1","g") }
$ gawk -f tst.awk file
Norman Normalrecord
norman#ooga.com
123 Main street
Missy Missington
MISSING_EMAIL_ADDR
789 Back street
Reggie Regularrecord
reggie#booga.com
456 Middle street
You can do the same in any awk using sub(/^..) then gsub(/\n...) instead of gensub(/(^|\n)...).
In case it's useful, to identify ANY missing field and provide a "missing" indication for it in the order the fields are used in your input and without having to explicitly name any of the fields up front (assume every field appears in at least one record) would be:
$ cat tst.awk
BEGIN { RS=""; FS=OFS="\n" }
{
for (fldNr=1; fldNr<=NF; fldNr++) {
split($fldNr,nameVal,/:[[:space:]]*/)
name = nameVal[1]
val = nameVal[2]
rec[NR,name] = val
if (!seen[name]++) {
for (nameNr=++numNames; nameNr>fldNr; nameNr--) {
names[nameNr] = names[nameNr-1]
}
names[nameNr] = name
}
}
}
END {
for (recNr=1; recNr<=NR; recNr++) {
for (nameNr=1; nameNr<=numNames; nameNr++) {
name = names[nameNr]
key = recNr SUBSEP name
if (key in rec) {
print rec[key]
}
else {
print "MISSING_" toupper(name)
}
}
print ""
}
}
$
$ cat file
Name: Norman Normalrecord
Email: norman#ooga.com
Addr: 123 Main street
Name: Missy Missington
Addr: 789 Back street
Name: Reggie Regularrecord
Email: reggie#booga.com
Addr: 456 Middle street
Whatever: Some useful info
$
$ awk -f tst.awk file
Norman Normalrecord
norman#ooga.com
123 Main street
MISSING_WHATEVER
Missy Missington
MISSING_EMAIL
789 Back street
MISSING_WHATEVER
Reggie Regularrecord
reggie#booga.com
456 Middle street
Some useful info

Answer 4

Here is a sed script that seems to do what you "dream" about (it assumes that the entries are separated with blank lines):
$ cat s.sed
# collect the lines from one entry in the pattern space
# removing the empty line for consistency
:a; $!{N;/\n$/!ba}; s/\n$//
# make substitutions
/Name:/!s/^/MISSING_NAME\n/
/Email:/!s/\n/\nMISSING_EMAIL_ADDR\n/
/Addr:/!s/$/\nMISSING_STREET_ADDR/
# add an empty line back
s/$/\n/p
With your data:
$ sed -nf s.sed info.txt
Name: Norman Normalrecord
Email: norman#ooga.com
Addr: 123 Main street
Name: Missy Missington
MISSING_EMAIL_ADDR
Addr: 789 Back street
Name: Reggie Regularrecord
Email: reggie#booga.com
Addr: 456 Middle street
Another demo:
$ cat info_ext.txt
Email: norman#ooga.com
Addr: 123 Main street
Name: Missy Missington
Addr: 789 Back street
Name: Reggie Regularrecord
Email: reggie#booga.com
$ sed -nf s.sed info_ext.txt
MISSING_NAME
Email: norman#ooga.com
Addr: 123 Main street
Name: Missy Missington
MISSING_EMAIL_ADDR
Addr: 789 Back street
Name: Reggie Regularrecord
Email: reggie#booga.com
MISSING_STREET_ADDR