Why is my filesize the same after adding further data? - perl

Question

Having some trouble with Perl (I am brand new at it). I have one .txt file in the same directory. I'm planning to copy the file, print it to stdout, add more text to the copy, and compare file sizes. This is what I have so far:
#!/usr/local/bin/perl
use File::Copy;
copy("data.txt", "copyOfData.txt") or die "copy failed :(";
open (MYFILE, "data.txt") or die "open failed :(";
while (<MYFILE>) {
chomp;
print "$_\n";
}
$filesize = -s MYFILE;
print "MYFILE filesize is $filesize\n";
close (MYFILE);
open(MYCOPYFILE, ">>copyOfData.txt");
print MYCOPYFILE "\nextra data here blah blah blah\n";
$filesize = -s MYCOPYFILE;
print "MYCOPYFILE filesize is $filesize\n";
close (MYCOPYFILE);
However, the output I'm getting is as follows:
MYFILE filesize is 28
MYCOPYFILE filesize is 28
Surely the MYCOPYFILE size should be bigger than the MYFILE size as I've added extra text? I have checked both text files and the copy does have the extra text at the end.
Thanks for your help!

Answer 1

You can check the size of the file using the filename (you don't have to open it).
my $size = -s 'data.txt' ;
And you should always start your script with
use strict ;
use warnings ;
And opening files is better done with the three-argument-version of open
open my $filehandle , '<' , 'filename' or die "Failed to open: $!" ;

Answer 2

$filesize = -s MYFILE;
As pointed out above, -s doesn't work on filehandles. If you want to get the size from a file handle, use stat
$filesize = ((stat(MYFILE))[7]);
See perldoc -f -X for details of -s and friends, see perldoc -f stat for stat

Answer 3

Check the filesize after closing the file.
If this does not change the filesize try adding more text, maybe the size wil change then.
Greetings

Answer 4

dgw's answer is correct.
Another way is to use File::stat as:
#!/usr/bin/perl
use strict;
use warnings;
use File::stat;
my $filesize = stat("test.txt")->size;
print "Size: $filesize\n";
exit 0;

Answer 5

Perl automatically do some buffering operation on IO objects. The contents may not be written to disk right after you call print FH "blalba". However, the -s function reads file size from disk. So when you think you have "updated" the file, you might get the size smaller than expected.
To get the correct size, flush the content in the buffer to the disk and then fetch the size with -s. Note that close(FH) will first flush the buffer automatically and then close the file handle. So you can put the -s operation after the close call to get accurate size.
Or, flush the buffer explicitly by calling flush() of IO::Handle before getting size:
open(MYCOPYFILE, ">>copyOfData.txt");
print MYCOPYFILE "\nextra data here blah blah blah\n";
MYCOPYFILE->flush();
$filesize = -s MYCOPYFILE;
print "MYCOPYFILE filesize is $filesize\n";
-s operates on file handle, directory handle and expression representing file name. So your code about -s works fine.