Test::MockObject::Extends with 'fields' gives error - perl

Question

So trying to upgrade some old test modules written by other people to support newer perls. Some of the tests are using Test::MockObject::Extends, but I've found running the following code errors out.
#!/usr/bin/env perl
package MyModule;
use strict;
use warnings;
use fields qw(field1 field2);
sub new {
my $self = shift;
unless (ref $self) {
$self = fields::new($self);
}
return $self;
}
package main;
use strict;
use warnings;
use Test::MockObject::Extends;
use Data::Dumper;
my $VAR1 = MyModule->new();
print Data::Dumper::Dumper($VAR1);
my $VAR2 = Test::MockObject::Extends->new($VAR1);
Error:
$ perl a
$VAR1 = bless( {}, 'MyModule' );
Modification of a read-only value attempted at /usr/local/share/perl/5.14.2/Test/MockObject/Extends.pm line 31.
I've looked at the changelog for Test::MockObject and perl 5.10 and can't see anything that directly looks like it causes this. I suspect its been broken for a while and something new for 5.10 just illuminated it.

Answer 1

I think what's happening here is a result of using fields::new. From the perldoc page:
perl 5.9.0 and higher: fields::new() creates and blesses a
restricted-hash comprised of the fields declared using the "fields"
pragma into the specified class.
I think Test::MockObject::Extends wants to modify the hash, hence boom.

Answer 2

#nfg's answer is correct, but there is a simple workaround: unlock the hash created by fields before passing it to Test::Object::Extends.
use Hash::Util qw(unlock_keys);
my $obj = Some::Class->new();
unlock_keys(%$obj);
$obj = Test::MockObject::Extends->new($obj);
This will fail if using a perl < 5.9, so if that is a concern then you could unlock the keys conditionally.
You may want to re-lock the keys after calling Test::MockObject::Extends and mocking any methods you want to intercept, because otherwise errant code that is accessing fields that should not exist in the object will not be caught.