Perl syntax usage, use strict and local - perl

Question

I have problem with Perl local syntax.
The code is below:
#!/usr/bin/perl -w
&outer;
sub outer {
local $lvar = 'local';
&inner;
}
sub inner {
print "lvar: $lvar\n";
}
If I run the code, it outputs:
lvar: local
But if the code is modified as below:
#!/usr/bin/perl -w
use strict;
&outer;
sub outer {
local $lvar = 'local';
&inner;
}
sub inner {
print "lvar: $lvar\n";
}
Then, errors occur:
Global symbol "$lvar" requires explicit package name at ./test.pl line 7.
Global symbol "$lvar" requires explicit package name at ./test.pl line 12.
Execution of ./test.pl aborted due to compilation errors.
I am confused here. I want to minimize the scope of $lvar, and I also want to use strict directive. But it seems they can not coexist.
Can use strict; and local coexist? Or, shall I state our $lvar?

Answer 1

local is almost never what you want. Use my, which declares a variable that is visible throughout (the rest of) an enclosing block.
It's unclear exactly what you want to do, but if you need to share a variable between two subroutines and protect it from access elsewhere then you can write something like this. Note that this is a closure and the value of $lvar is persistent across calls to either subroutine.
Note that you shouldn't call subroutines using the &subname syntax. That has been wrong since Perl 5 was introduced in 1994. Use subname() instead.
use strict;
use warnings;
outer();
{
my $lvar;
sub outer {
$lvar = 'local';
inner();
}
sub inner {
print "lvar: $lvar\n";
}
}

Answer 2

Use my to declare lexical variables. How about this rewrite?
#!/usr/bin/perl
use strict;
use warnings;
outer();
sub outer {
my $lvar = 'local';
inner($lvar);
}
sub inner {
my $lvar = shift;
print "lvar: $lvar\n";
}
Resources:
Coping with Scoping (includes discussion of my versus local).
Another good resource is the book Modern Perl. Just search for "lexical".

Answer 3

local does not declare/create variables — it just creates an auto-restoring backup of an existing variable — so you still have to declare $lvar. Since local only works with package variables[1], this is one of the rare occasions where one needs to use our instead of my.
outter();
sub outter {
local our $lvar = 'local';
inner();
}
sub inner {
our $lvar;
print "lvar: $lvar\n";
}
You could also declare the variable "globally".
our $lvar;
outter();
sub outter {
local $lvar = 'local';
inner();
}
sub inner {
print "lvar: $lvar\n";
}
Or just once for the two subs.
outter();
{
our $lvar;
sub outter {
local $lvar = 'local';
inner();
}
sub inner {
print "lvar: $lvar\n";
}
}
But really, local is something you should only want to use when you are forced to use package variables. When creating your own variables, you want to use my instead.
outter();
{
my $lvar;
sub outter {
$lvar = 'local';
inner();
}
sub inner {
print "lvar: $lvar\n";
}
}
It also works with hash elements and array elements of both lexical and package variables.