I'm trying to figure out a way to connect to my iPhone via Bluetooth with a shell script. I'm currently using an applescript which essentially does this through UIElements, but I'm wondering if this can be done with a command line utility, a.l.a. blueutil but with the ability to connect to the device not just turn on/off bluetooth? Thanks for the consideration.
-Afshin
This answer is very similar to #Wolph's answer; however after fighting other issues this is what I came up with. I like it better for two reasons:
# It will not disconnect the device if it is already connected
# Nice output from osascript
Just save it in a file and call osascript path/to/file.applescript
This was working on OSX Mavericks 10.9.2 as of 11-Apr-2014, although you may need to grant access to whatever method you use to run this in the security preferences panel. See this Apple KB: http://support.apple.com/kb/HT5914
All you should have to do is change the "LG HBS730" string to match the name of your device and you should be set. The returns are there so you get nice output from osascript.
activate application "SystemUIServer"
tell application "System Events"
tell process "SystemUIServer"
-- Working CONNECT Script. Goes through the following:
-- Clicks on Bluetooth Menu (OSX Top Menu Bar)
-- => Clicks on LG HBS730 Item
-- => Clicks on Connect Item
set btMenu to (menu bar item 1 of menu bar 1 where description is "bluetooth")
tell btMenu
click
tell (menu item "LG HBS730" of menu 1)
click
if exists menu item "Connect" of menu 1
click menu item "Connect" of menu 1
return "Connecting..."
else
click btMenu -- Close main BT drop down if Connect wasn't present
return "Connect menu was not found, are you already connected?"
end if
end tell
end tell
end tell
end tell
I had to change a bit to get Andrew Burns's answer to work for me in Yosemite; his code keeps giving me
connect-mouse.scpt:509:514: execution error: System Events got an error: Can’t get menu 1 of menu bar item 3 of menu bar 1 of application process "SystemUIServer". Invalid index. (-1719)
Seems like selecting the menu bar item that way lets you click on it, but not get to the menu, for some inscrutable applescript reason. This very similar code works for me:
tell application "System Events" to tell process "SystemUIServer"
set bt to (first menu bar item whose description is "bluetooth") of menu bar 1
click bt
tell (first menu item whose title is "The Device Name") of menu of bt
click
tell menu 1
if exists menu item "Connect"
click menu item "Connect"
return "Connecting..."
else
click bt -- close main dropdown to clean up after ourselves
return "No connect button; is it already connected?"
end if
end tell
end tell
end tell
I don't know the difference between (first menu bar item whose description is "bluetooth") of menu bar 1 and (menu bar item 1 of menu bar 1 where description is "bluetooth"), but....
Updating this for High Sierra 10.13.2, based on the answers provided by Andrew Burns and dougal.
set DeviceName to "LG HBS730"
tell application "System Events" to tell process "SystemUIServer"
set bt to (first menu bar item whose description is "bluetooth") of menu bar 1
click bt
if exists menu item DeviceName of menu of bt then
tell (first menu item whose title is DeviceName) of menu of bt
click
tell menu 1
if exists menu item "Connect" then
click menu item "Connect"
return "Connecting..."
else
key code 53 -- hit Escape to close BT menu
return "No connect button; is it already connected?"
end if
end tell
end tell
else
key code 53 -- hit Escape to close BT menu
return "Cannot find that device, check the name"
end if
end tell
Changes:
Clicking on the Bluetooth icon no longer closes the menu. Solved by hitting the Escape key, per this answer and confirmed on this page
Checking to see if the device is listed in Bluetooth menu, to detect incorrect names. (I spent quite a while debugging, only to realize ' isn't the same as ’...)
Hope this helps others, not trying to steal karma!
After messing about a bit with Applescript I wrote this little bit of Applescript to connect:
Note that the "Show Bluetooth in menu bar" checkbox needs to be on for this as it's effectively just using that menu.
tell application "System Events"
tell process "SystemUIServer"
tell (menu bar item 1 of menu bar 1 whose description is "bluetooth")
click
-- You can use your phone name as well over here if you have multiple devices
-- tell (menu item "YOUR_PHONE_NAME_HERE" of menu 1)
tell (menu item 1 of menu 1)
click
tell (menu item 1 of menu 1)
click
end tell
end tell
end tell
end tell
end tell
This tool1 allowed me to connect to bluetooth headphones from command line.
As far as I know you can only turn on/off bluetooth and check the status in command line (using blueutil or manipulating with launchctl). But you can use your applescript routines via osascript in shell.
Dougal's answered worked for me.
You can also use Automator to create a service that can be run from anywhere and assign it a Keyboard Shortcut in Keyboard Shortcut Preferences for an even faster workflow.
I have multiple bluetooth audio device(s). So Andrew's script is very helpful. Here's my modification to his script. I'm not a programmer/IT person, just learned some bits from the internet.
set btchoice to BT_Choice()
on BT_Choice()
display dialog "Choose the device of your choice" with title "Selecting Device" buttons {"Bluedio", "Reconnect S-TS", "Anker A7721"} default button "Reconnect S-TS"
set Ndialogresult to the result
set DNameSel to button returned of Ndialogresult
display dialog "Whether to Connect or Disconnect the Device" with title "Handling Bluetooth" buttons {"Connect", "Disconnect", "Cancel"} default button "Connect"
set Bdialogresult to the result
set Bbuttonsel to button returned of Bdialogresult
activate application "SystemUIServer"
tell application "System Events"
tell process "SystemUIServer"
set btMenu to (menu bar item 1 of menu bar 1 where description is "bluetooth")
tell btMenu
click
tell (menu item DNameSel of menu 1)
click
if exists menu item Bbuttonsel of menu 1 then
click menu item Bbuttonsel of menu 1
return "Connecting..."
else
click btMenu -- Close main BT drop down if Connect wasn't present
return "Connect menu was not found, are you already connected?"
end if
end tell
end tell
end tell
end tell
end BT_Choice
Related
I'm trying to add shortcuts to my Notes app for typing in superscript and subscript. The script below does not give any errors and correctly seems to find/click the 'Superscript' submenu item, but when returning to the notes app this option is not activated/selected. If I uncomment the line below it, that functionality (opening 'Notes Help') works perfectly.
tell application "System Events"
tell process "Notes"
click menu item "Superscript" of menu 1 of menu item "Baseline" of menu 1 of menu item "Font" of menu "Format" of menu bar 1
-- click menu item "Notes Help" of menu "Help" of menu bar 1
end tell
end tell
What am I doing wrong?
AppleScript code is usually all about personal style, but I just wrote this up real quick from probing the menubar. Tested and working properly.
tell application "Notes" to activate -- needed because you say "but when returning to the notes app" meaning you're not there already
-- tell System Events to Click, not tell system events to tell process to click... process doesn't understand click.
tell application "System Events"
click menu item "Superscript" of menu "Baseline" of menu item "Baseline" of menu "Font" of menu item "Font" of menu "Format" of menu bar item "Format" of menu bar 1 of application process "Notes" of application "System Events"
end tell
For instance, what is the pure Swift equivalent of the following AppleScript:
tell application "System Events" to tell process "Finder"
click menu item "New Finder Window" of menu 1 of menu bar item "File" of menu bar 1
end tell
What I'm trying to do is set up a smart Mailbox that will take a list of companies mailboxes that I'm assigned per day (ranges anywhere between 8 to 30 depending on the size of the account and the number of people working) so I can watch and assist the companies. Ideally what the script would do is accept a list of companies and then go through the mailboxes and add them to the smart mailbox like "Messages in mailbox" "Company A" but company A is in Mailbox > Letter > Company. Here is what I have so far.
set CustomerNames to {"Example, A"}
set CustomerNumber to 1
display dialog "What are the Customer's Names?" default answer ""
set CustomerNames to text returned of result
tell application "Mail" to activate
tell application "System Events"
tell process "Mail"
tell menu bar 1
tell menu bar item "Mailbox"
tell menu "Mailbox"
click menu item "New Smart Mailbox…"
end tell
end tell
end tell
end tell
keystroke "w" using shift down
keystroke "orklist2"
keystroke tab
keystroke "a"
delay 2
keystroke tab
key code 31 using control down -- Down Arrow
delay 2
tell process "Mail"
get the name of front Mail window
get the name of the selected menu
click menu item "Message is in mailbox"
keystroke tab
set the popupbutton to "CustomerNames"
click menu item "add criterion"
end tell
end tell
tell application "System Events"
repeat with CustomerNames from 1 to count of CustomerNames
click menu item "add criterion"
set the popupbutton to menu 13
set CustomerNumber to CustomerNames add 1
end repeat
keystroke return
end tell
This is probably a very stupid question,
However I need to code within an App, I've been using UIbutton for a while but is not good enough, My app have a .framework files,
Can I use this for scripting ?
Example if I want a click on a button listed, is there anyway to do that?
1 button
1 button
The AppleScript framework is not available on iOS
You can do this with AppleScript and System Events. Here how you can click in a menu of the application Finder.
tell application "Finder" to activate
tell application "System Events"
tell process "Finder"
tell menu bar item 2 of menu bar 1
click
end tell
end tell
end tell
I want to create an AppleScript to click a menu but I can't what ever the script I using, here is the menu I want :
ELEMENT :
Role : menu item
Title: "sign in As..."
Description :
Help:
Application: SytemUIServer
ELEMENT PATCH (starting at leaf element):
menu Item "Sign in As..." (menu item 12)
menu (menu 1)
menu extra (menu bar item 2)
menu bar (menu bar 1)
application "SystemUIServer"
So I did a few script, the last one was
ignoring application responses
tell application "System Events" to tell process "SystemUIServer"
click menu bar item 2 of menu bar 1
end tell
end ignoring
do shell script "killall System\\ Events"
delay 0.1
tell application "System Events" to tell process "SystemUIServer"
tell menu item 12 of menu 1 of menu bar item 2 of menu bar 1
click
end tell
end tell
Also I just realise that the position can change (some time the item I want to click is menu item 12 sometime its 10 etc.)
In your question, you didn't specify name of the menu bar item and name of the app which owns the menu bar item. That's the problem.
First, SystemUIServer only run menu bar items/icons native to OS X. To see the icons it runs, do these three lines separately in Script Editor.
1)
tell application "System Events" to tell process "SystemUIServer" ¬
to number of menu bars
2)
tell application "System Events" to tell process "SystemUIServer" ¬
to value of attribute "AXDescription" of menu bar items of menu bar 1
3)
tell application "System Events" to tell process "SystemUIServer" ¬
to title of menu bar items of menu bar 2
The results should look something like:
1) 2
2) {"Wi-Fi, four of four bars, with WiFiName.", "Battery: Charged ", "Clock"}
3) {"Notification Center", missing value}
Third-party apps, plus Spotlight, manage its own menu bar items/icons. Spotlight for example:
tell application "System Events" to tell process "Spotlight" ¬
to title of menu bar items of menu bar 1
This gives you: {"Spotlight"}
If you have Caffeine:
tell application "System Events" to tell process "Caffeine" ¬
to title of menu bar items of menu bar 1
You get: {missing value}, 'cause its programer didn't bother naming the item.
So if this is third-party menu bar item you are trying to script, it's not in SystemUIServer. If you only refer to the menu bar item with position instead of its name, you cannot reliably click it every time.
McUsr inserted this line, in order to save the edit that had to be of minimum 6 characters.