mapping hardcoded config files - perl

Question

I have searched for modules to read config files such as Config, Config::Tiny, Config::Simple. I am not too vague about using those, are there any modules for storing/reading dbi config and usernames/passwords? I have attempted to do this myself, I am wanting to have the config file in a hash data structure for easy importing into my module. Is their an easier way to do what I am attempting or a preferred module that could be suggested?
Example config file:
[database]
db=newsdb
host=example.com
user=test
pass=test
[login]
user=john
pass=doe
Coding:
use strict;
use warnings;
use File::Slurp;
use Data::Dumper;
# get database info
my %conf =
map { /^\[database/ ? () : $_ }
grep { /^\w+.*$/ }
map { s/\s?\n?\r?//g; (split /=/)[0,1] } read_file('database.conf');
print Dumper \%conf;
$VAR1 = {
'pass' => 'test',
'db' => 'newsdb',
'user' => 'test',
'host' => 'example.com'
};

Answer 1

The Config module is not used to read configuration files, it gives detailed information on the configuration of your perl instead.
An easy route here would be to use Config::Simple, and then
Config::Simple->import_from("database.conf" => \my %config);
print Dumper \%config;
Output:
$VAR1 = {
'database.host' => 'example.com',
'login.pass' => 'doe',
'login.user' => 'john',
'database.user' => 'test',
'database.db' => 'newsdb',
'database.pass' => 'test'
};
Alternatively, to access just one block, we could do
my $config = Config::Simple->new("database.conf")->get_block("database");
print Dumper $config;
which would give
$VAR1 = {
'pass' => 'test',
'db' => 'newsdb',
'user' => 'test',
'host' => 'example.com'
};
as output. Read the documentation for more information.
It gets even simpler with Config::Tiny:
my $config = Config::Tiny->read("database.conf");
print Dumper $config;
would give
$VAR1 = bless( {
'database' => {
'pass' => 'test',
'db' => 'newsdb',
'user' => 'test',
'host' => 'example.com'
},
'login' => {
'pass' => 'doe',
'user' => 'john'
}
}, 'Config::Tiny' );
so the database portion could be selected with
print Dumper $config->{database}
which would output
$VAR1 = {
'pass' => 'test',
'db' => 'newsdb',
'user' => 'test',
'host' => 'example.com'
};
You can learn more in the documentation.