Input a .i in a progress 10.2b - progress-4gl

Question

I'm inputting a file that needs to be converted to an xml file but I also want to input a .i with the definition of the temp table used to create the xml. Also the delimiter isn't working (I need a way to convert a variable to something the command can read). Thanks!
define input parameter pInputFile as character no-undo.
define input parameter pDelimiter as character no-undo.
???define input parameter pIncludeFile as character no-undo.???
define output parameter pOutputFile as character no-undo init "/tmp/out..
/* start of .i */
define temp-table ttGeneric no-undo
field cust_id as integer
field name as character
field address as character
field address2 as character
field city as character
field state as character
field zip as character
field cust_key as character
index idx is primary cust_id.
/* end of .i */
input stream sImport from value(pInputFile) no-echo.
repeat:
create ttGeneric.
import stream sImport delimiter pDelimiter ttGeneric.
end.
input stream sImport close.
temp-table ttGeneric:write-xml("LONGCHAR", pOutputFile, yes).
maybe set a pre-processor in the calling program (some how).

Answer 1

Delimiters to IMPORT and EXPORT must be literal strings. You cannot use variables, fields, parameters or anything like that.
I have, on occasion, worked around that with a CASE statement. i.e.:
case pDelimiter:
when "," then import stream sImport delimiter "," ttGeneric.
when "|" then import stream sImport delimiter "|" ttGeneric.
end.
Ugly. But it works.
I think you might be trying to say that you want to pass the name of an include file that contains a TT definition? And somehow associate that definition with a temp-table?
If that is more or less correct then you are probably being too specific about your requirement -- you probably really just want to dynamically create a TT whose definition is external to the program and unknown at compile time.
One way to do that is to use the read-xmlschema() method -- you're already using write-xml() so it's a small step... first convert your .i to a little .p like so:
define temp-table ttGeneric no-undo
field cust_id as integer
field name as character
field address as character
field address2 as character
field city as character
field state as character
field zip as character
field cust_key as character
index idx is primary cust_id.
buffer ttGeneric:write-xmlschema( "file", "ttgeneric.xsd", true, ?, ?, ? ).
return.
(This little stub lets you create the .XSD file. It serves no other purpose. Just run it once to get that file.)
Then when you want to use that temp-table:
define variable tx as handle no-undo.
create temp-table tx.
tx:read-xmlschema( "ttgeneric.xsd", "file", ?, ?, ? ).
(Note: Unlike with delimiters you can use variables & parameters etc. for the xsd name and it could be in a longchar rather than a file...)
The next adventure you will run into is figuring out a replacement for IMPORT that works with dynamic temp-tables. Buffer handles don't have import() and export() methods :(
The following snippets may help:
define variable dummy as character no-undo extent 128.
...
dummy = ?.
import dummy.
...
do i = 1 to 128:
if dummy[i] = ? then leave.
tx:buffer-field( i ):buffer-value() = dummy[i].
end.