perl: why not returning for case 0 or 1? - perl

Question

I am implementing a perl fib with hash table:
#!/usr/bin/perl
use strict;
use warnings;
no warnings 'recursion';
my %m_fib = (0,1,1,1);
while (my $a = <STDIN>) {
print "--".&fib($a)."\n";
}
sub fib {
foreach my $i (#_) {
if (not defined $m_fib{$i}) {
$m_fib{$i} = &fib($i - 1) + &fib($i - 2);
}
return $m_fib{$i};
}
}
It is working well with input larger than 1, but silent with either 0 or 1.
The hash should be fine since it is returning the correct result, but why it won't work if I feed that with 0 or 1?

Answer 1

Your input contains the end of line (\n). Remove it with chomp (documentation)
while (my $a = <STDIN>) {
chomp $a;
print "--".&fib($a)."\n";
}
Edit: What the problem is
with any input the defined test will always fail as the string number\n is not present in the hash
Perl is able to perform a mathematical operation with your input 20\n - 1 is 19
Now with 0 or 1 no defined value is found and your code will call fib(-1) and fib(-2) or fib(0) and fib(-1) respectively. This will generate an endless loop.
With 2 the test will fail and Perl will perform the subtraction calling fib(1) + fib(0) (without the \n). In the second call your test will work as $m_fib(0) does indeed exist.
Edit 2
A small review with a few comments
your function processes more than one argument but exits after the first one. You never call it with more than one argument (and even if you did it will never process the second)
some other comments inline (you can review you code using Perl::Critic)
#!/usr/bin/perl
use strict;
use warnings;
# Not needed
# no warnings 'recursion';
my %m_fib = ( 0, 1, 1, 1 );
# From Perl::Critic
#
# Use "<>" or "<ARGV>" or a prompting module instead of "<STDIN>" at line 10, column 17.
# InputOutput::ProhibitExplicitStdin (Severity: 4)
# Perl has a useful magic filehandle called `*ARGV' that checks the
# command line and if there are any arguments, opens and reads those as
# files. If there are no arguments, `*ARGV' behaves like `*STDIN' instead.
# This behavior is almost always what you want if you want to create a
# program that reads from `STDIN'. This is often written in one of the
# following two equivalent forms:
#
# while (<ARGV>) {
# # ... do something with each input line ...
# }
# # or, equivalently:
# while (<>) {
# # ... do something with each input line ...
# }
#
# If you want to prompt for user input, try special purpose modules like
# IO::Prompt.
while ( my $a = <> ) {
chomp $a;
# use " just when needed
print '--' . fib($a) . "\n";
}
sub fib {
my $i = shift;
if ( not defined $m_fib{$i} ) {
# it is not necessary to use & for subroutine calls and
# can be confused with the logical and
$m_fib{$i} = fib( $i - 1 ) + fib( $i - 2 );
}
return $m_fib{$i};
}