Perl - combine two split commands into one - perl

Question

I have a perl script that I was cleaning up, it works very well, but I was wondering if anyone knows of a good way to combine 2 splits into one command.
I have a .csv file, like this small example:
Move_VALIDATE,020212191ABC01,SNSNT---01CAB101A-1-1-4-20,circuit 402339-1,interface 1/1/0
Move_VALIDATE,030323202ABC01,SNSNT01CAB101A-1-1-4-20,circuit 303559-1,interface 2/2/0
Section in script with the two splits:
foreach my $line (#file_array){
my $CHECK_ID = (split /,/, $line) [2];
my #SPLIT_ID = (split /-/, $CHECK_ID);
my $FINAL_ID = ($CHECK_ID =~ /---/) ? "$SPLIT_ID[0]---$SPLIT_ID[3]" : "$SPLIT_ID[0]";
print "$FINAL_ID\n";
}
Output:
SNSNT---01CAB101A
SNSNT01CAB101A

Answer 1

First, if you have long lines with many fields, it pays to limit how many fields you are asking split to return. In this case, you need the third field, so you want to limit split to four fields.
Second, it is easier to remove the part you don't need at the end of the field.
#!/usr/bin/env perl
use strict;
use warnings;
while (my $line = <DATA>) {
(my $id = (split /,/, $line, 4)[2]) =~ s/(?:-[0-9]{1,2})+\z//;
print "$id\n";
}
__DATA__
Move_VALIDATE,020212191ABC01,SNSNT---01CAB101A-1-1-4-20,circuit 402339-1,interface 1/1/0
Move_VALIDATE,030323202ABC01,SNSNT01CAB101A-1-1-4-20,circuit 303559-1,interface 2/2/0
$ ./klklj.pl
SNSNT---01CAB101A
SNSNT01CAB101A

Answer 2

You can use one split for commas as you have it and use word-boundary assertion for the second one, like:
#!/usr/bin/env perl
use strict;
use warnings;
while (<DATA>) {
chomp;
printf qq|%s\n|, (split /\b-\b/, (split /,/, $_)[2])[0];
}
__DATA__
Move_VALIDATE,020212191ABC01,SNSNT---01CAB101A-1-1-4-20,circuit 402339-1,interface 1/1/0
Move_VALIDATE,030323202ABC01,SNSNT01CAB101A-1-1-4-20,circuit 303559-1,interface 2/2/0
Run it like:
perl script.pl
That yields:
SNSNT---01CAB101A
SNSNT01CAB101A