Progress indicator for Perl LWP POST upload - perl

Question

I'm working on a Perl script which uploads big files with a POST request. My question is if it's possible to have a status output, because uploading big files can take some time with my internet connection.
I mean like a status bar with
$| = 1;
print "\r|----------> | 33%";
print "\r|--------------------> | 66%";
print "\r|------------------------------| 100%\n";
Here's my upload code:
my $ua=LWP::UserAgent->new();
$file = "my_big_holyday_vid.mp4";
$user = "username";
$pass = "password";
print "starting Upload...\n";
$res = $ua->post(
"http://$server",
Content_Type => 'form-data',
Content =>[
fn => ["$file" => $file],
username => $user,
password => $pass,
],
);
print "Upload complete!\n"

Answer 1

If you look at the documentation for HTTP::Request::Common you will see that, if you set $HTTP::Request::Common::DYNAMIC_FILE_UPLOAD to a true value, then the request object's content method will provide a callback that is used to fetch the data in chunks.
Normally this is called each time more data is needed for upload, but you can wrap it in your own subroutine to monitor the progress of the upload.
The program below gives an example. As you can see, the HTTP::Request object is created (I have assumed that the fn field should be just [$file]) and the content method is used to fetch the callback subroutine.
The subroutine wrapper just calls $callback in the first line to fetch the next data chunk, and returns it in the last line, just as $callback itself would do. Between these two lines you can add what you like, as long as it doesn't interfere with passing the chunk back to LWP. In this case I have printed the size of each chunk together with the percentage upload so far on each call.
For the purpose of percentage calculations, the full size of the file is accessible as $req->header('content-length'), which is more correct than using -s on the file.
Also, the final iteration can be detected if necessary as the callback will return chunk with a size of zero.
Note that this is untested except as far as it compiles and does roughly the right thing, as I have no internet service available that expects a file upload.
use strict;
use warnings;
use LWP;
use HTTP::Request::Common;
$HTTP::Request::Common::DYNAMIC_FILE_UPLOAD = 1;
my $ua = LWP::UserAgent->new;
my $server = 'example.com';
my $file = 'my_big_holyday_vid.mp4';
my ($user, $pass) = qw/ username password /;
print "Starting Upload...\n";
my $req = POST "http://$server",
Content_Type => 'form-data',
Content => [
fn => [$file],
username => $user,
password => $pass,
];
my $total;
my $callback = $req->content;
my $size = $req->header('content-length');
$req->content(\&wrapper);
my $resp = $ua->request($req);
sub wrapper {
my $chunk = $callback->();
if ($chunk) {
my $length = length $chunk;
$total += $length;
printf "%+5d = %5.1f%%\n", $length, $total / $size * 100;
}
else {
print "Completed\n";
}
$chunk;
}