Transaction lock not releasing on the last record - progress-4gl

Question

I have an include file with 2 functions. One of the functions works perfectly fine so I won't include it in this. I will include the function that is causing the issue.
The ss_update function is the one causing me issue and not releasing the lock as I assumed it would. I finally got to work this way adding the find current screenstate no-lock. statement. I wondering if someone can explain this to me and if there is a better way to handle this situation.
FUNCTION ss_update RETURNS INTEGER
( INPUT iUserName AS CHAR,
INPUT iScreenName AS CHAR,
INPUT iWidgetName AS CHAR,
INPUT iWidgetValue AS CHAR ):
DEFINE VARIABLE retStatus AS INTEGER NO-UNDO.
FIND ScreenState EXCLUSIVE-LOCK WHERE ScreenState.userName = iUserName AND
ScreenState.screenName = iScreenName AND
ScreenState.widgetName = iWidgetName NO-ERROR.
IF AVAIL ScreenState THEN
DO:
IF ScreenState.widgetValue <> iWidgetValue THEN
DO:
ASSIGN
ScreenState.widgetValue = iWidgetValue.
END.
retStatus = 1.
END.
IF NOT AVAIL ScreenState THEN
DO:
CREATE ScreenState.
ASSIGN
ScreenState.screenStateId = NEXT-VALUE(seq-ScreenStateId)
ScreenState.userName = iUserName
ScreenState.screenName = iScreenName
ScreenState.widgetName = iWidgetName
ScreenState.widgetValue = iWidgetValue.
retStatus = 2.
END.
/* This was added to release the lock. */
FIND CURRENT screenstate NO-LOCK.
RETURN retStatus.
END FUNCTION.
I have code that will call the update function several times in a row. Like this...
ss_update(USERID(LDBNAME(1)), "FindComp2.w", "t-ActiveOnly", t-ActiveOnly:SCREEN-VALUE).
ss_update(USERID(LDBNAME(1)), "FindComp2.w", "t-BadAdd", t-BadAdd:SCREEN-VALUE).
ss_update(USERID(LDBNAME(1)), "FindComp2.w", "LastCompany", company.companyId).
ss_update(USERID(LDBNAME(1)), "FindComp2.w", "rs-Filter", rs-Filter:SCREEN-VALUE).
ss_update(USERID(LDBNAME(1)), "FindComp2.w", "cb-Salesman", cb-Salesman:SCREEN-VALUE).
ss_update(USERID(LDBNAME(1)), "FindComp2.w", "cb-Search", cb-Search:SCREEN-VALUE).
ss_update(USERID(LDBNAME(1)), "FindComp2.w", "scr-Search", TRIM(scr-Search:SCREEN-VALUE)).
The problem I was having was that progress wasn't releasing the lock from the last called ss_update function. I had to add find current screenstate no-lock to downgrade the lock. This just seems ugly and not properly coded and was wondering why this happened and what is the proper way to handle this such issue.

Answer 1

Your record buffers are weakly scoped and there is likely a reference to ScreenState somewhere in the program that includes this function.
The function is likely "borrowing" the record from the main block.
To fix it there are several possibilities. It is quick and dirty but one of the things that I like to do is to add:
define buffer ScreenState for ScreenState.
at the top of the function definition. This may look a little odd but what it does is to force all references to ScreenState to be local to the function. It stops the accidental "borrowing" of scope.
The ultimate solution is to strong scope the records and declare explicit transactions. That code would look like this:
FUNCTION ss_update RETURNS INTEGER
( INPUT iUserName AS CHAR,
INPUT iScreenName AS CHAR,
INPUT iWidgetName AS CHAR,
INPUT iWidgetValue AS CHAR ):
define buffer ScreenState for ScreenState. /* prevent accidents from happening... */
define buffer updScreenState for ScreenState. /* used for updates */
DEFINE VARIABLE retStatus AS INTEGER NO-UNDO.
do for updScreenState transaction:
FIND updScreenState EXCLUSIVE-LOCK WHERE
updScreenState.userName = iUserName AND
updScreenState.screenName = iScreenName AND
updScreenState.widgetName = iWidgetName NO-ERROR.
IF available updScreenState THEN
DO:
IF updScreenState.widgetValue <> iWidgetValue THEN
DO:
ASSIGN
updScreenState.widgetValue = iWidgetValue.
END.
retStatus = 1.
END.
IF NOT available updScreenState THEN
DO:
CREATE updScreenState.
ASSIGN
updScreenState.screenStateId = NEXT-VALUE(seq-ScreenStateId)
updScreenState.userName = iUserName
updScreenState.screenName = iScreenName
updScreenState.widgetName = iWidgetName
updScreenState.widgetValue = iWidgetValue.
retStatus = 2.
END.
end.
RETURN retStatus.
END FUNCTION.
The code above defines both ScreenState and updScreenState -- strictly speaking plain old ScreenState does nothing since there are no references to it. But if someone comes along later (or if I somehow missed one) it will prevent accidental references from having side-effects.
Using updScreenState makes it clear and obvious that the buffer is for update purposes.
The explicit TRANSACTION keyword clearly defines where you expect a transaction to start -- if the compiler objects to that then it is telling you that your code is trying to do something that you didn't expect.
The DO FOR block is what "strong scopes" the updScreenState buffer. The compiler will object if there are stray free references to updScreenState lying around outside that block.