How to make the points of a scatterplot semi-transparent with SPSS? - opacity

Question

I've made this graph with the SPSS base default scatterplot : I used the "Bin-element" and "Marker Size" options to regroup superposed points and make them easier to read. Here it is :
http://imageshack.com/a/img902/8746/pTRzJV.jpg
But I would like to get a graph that looks like this one :
http://espnfivethirtyeight.files.wordpress.com/2014/09/morris-feature-skepticnflweek2-2.png
The points of this graph are utilizing semi-transparency. I tried to find some stuff about opacity or semi-transparency, and I found only this ressource :
http://andrewpwheeler.wordpress.com/2012/06/17/visualization-techniques-for-large-n-scatterplots-in-spss/
Unfortunately, I don't understand how to do it... Could you please help me ?
By the way, do you know whether this graph has been made with SPSS or rather R ? Which tool would be the best for this kind of graphs ?
Thank you !

Answer 1

Here is a brief example. So first I will make some fake data.
INPUT PROGRAM.
LOOP ID = 1 TO 10000.
END CASE.
END LOOP.
END FILE.
END INPUT PROGRAM.
COMPUTE X = RV.NORMAL(0,1).
COMPUTE Y = RV.NORMAL(0,1).
Now, you cannot generate opacity within the GUI as far as I'm aware - you need to specify it in syntax. So go ahead and go through the Graph Builder GUI dialogue, specify the scatterplot you are interested in, and then paste the syntax. Here is what the default produces for me plus the graph (with my particular chart template).
GGRAPH
/GRAPHDATASET NAME="graphdataset" VARIABLES=X Y MISSING=LISTWISE REPORTMISSING=NO
/GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: X=col(source(s), name("X"))
DATA: Y=col(source(s), name("Y"))
GUIDE: axis(dim(1), label("X"))
GUIDE: axis(dim(2), label("Y"))
ELEMENT: point(position(X*Y))
END GPL.
Now you will need to edit the options on the second to last line, the ELEMENT statement. I am going to do two things; 1) make the points smaller and 2) make the exterior line of the points semi-transparent. Here is the code and the resulting graph follows.
GGRAPH
/GRAPHDATASET NAME="graphdataset" VARIABLES=X Y MISSING=LISTWISE REPORTMISSING=NO
/GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: X=col(source(s), name("X"))
DATA: Y=col(source(s), name("Y"))
GUIDE: axis(dim(1), label("X"))
GUIDE: axis(dim(2), label("Y"))
ELEMENT: point(position(X*Y), size(size."2"),
transparency.exterior(transparency."0.9"))
END GPL.