Determining file size in Perl doesn't always work - perl

Question

I'm trying to enumerate directory content and check the sizes of the files there (no recursion). So I opendir/readdir through the directory, skip certain types of files (directories and such), and by using something like my $size = -s "$file_path get the size of the current file.
However, I'm having a weird situation - in one directory I can't get the size of any file (containing all .exe files). The same program runs fine on another directory (.txt files, .pl and similar).
If I copy some .exe file from the first directory to the other one, its size is properly determined.
If I run the program on the first directory again, the size of that one copied .exe is properly determined, all others still fail. So it seems like some weird caching problem.
Any idea why this is happening?
Edit: With the -f check, the .exe files for which size check doesn't work are not plain files. However they "become" plain files if I just copy them from that directory somewhere. Then the size check works
The part of the code used for enumerating files:
my $dir_handle;
my $dir_entry;
my $retVal = opendir($dir_handle, "$path");
if (!$retVal)
{
print "Unable to open directory. \n$!";
exit(0);
}
while ($dir_entry = readdir($dir_handle))
{
print "Current file: $dir_entry \n";
next if (! -f $dir_entry);
my $size_bytes = -s "$dir_entry";
if ($size_bytes)
{
print "Size: $size_bytes \n";
}
}
closedir($dir_handle);

Answer 1

readdir() returns the file name only, and doesn't include the path information - so if the directory is not the same as the current working dir, this will fail.
You want to include the path:
while ($dir_entry = readdir($dir_handle))
{
print "Current file: $dir_entry \n";
next if (! -f "$path/$dir_entry");
my $size_bytes = -s "$path/$dir_entry";
if ($size_bytes)
{
print "Size: $size_bytes \n";
}
}
(and yes, using Unix-style path separators works fine here; feel free to use \ instead if you like escaping things)

Answer 2

readdir only returns the name of each directory entry. It doesn't include the path to the directory being read. For example, if you're reading /var/tmp and that directory contains a file named foo, then readdir is going to return foo, not /var/tmp/foo.
To check whether a directory entry is a file or to get its size, you have to provide a full pathname to the file, including the directory part. Unless you're specifically calling readdir on the current directory, you will need to convert each filename to a pathname:
while ($dir_entry = readdir($dir_handle))
{
my $pn = $path . '/' . $dir_entry;
print "Current file: $pn \n";
next if (! -f $pn);
my $size_bytes = -s $pn;
...
}

Answer 3

As has already been stated, your bug was in not including the path information during your file operations.
I would recommend using Path::Class to make your file and directory operations cross platform compatible, but also to automatically handle issues like this:
use strict;
use warnings;
use Path::Class;
my $path = '.';
my $dir = dir($path);
for my $child ( $dir->children ) {
printf "Current file: %s\n", $child->basename;
next if !-f $child;
if ( my $size = -s $child ) {
print "Size: $size\n";
}
}