BREAK BY With multiple joins in Progress ABL - progress-4gl

Question

I am trying to learn Progress ABL and I can not find a good example of using break by with multiple joins. The error I am getting right now is Colon followed by white space terminates a statement. (199).
The last time I ran into this error it was because I didn't have my end statement in the correct place, but I don't know if that is it or not. Any help is appreciated.
DEFINE QUERY q1
FOR platte.item FIELDS (item item_ptr costing_uom stocking_uom size description default_uom_conv_factor),
platte.item_branch FIELDS (weight_uom load_uom weight load_factor),
platte.item_uomconv FIELDS (system_id item_ptr_sysid),
platte.uom_conv FIELDS (convert_from convert_to conv_factor),
platte.product_group_minor FIELDS (major minor).
OPEN QUERY q1
FOR EACH item WHERE (item.system_id = '000000') NO-LOCK,
EACH item_branch WHERE (item_branch.system_id = item.system_id
AND item_branch.item_ptr = item.item_ptr) NO-LOCK,
EACH item_uomconv WHERE (item_uomconv.system_id = item.system_id
AND item_uomconv.item_ptr_sysid = item.system_id
AND item_uomconv.item_ptr = item.item_ptr) NO-LOCK,
EACH uom_conv WHERE (uom_conv.system_id = item_uomconv.uom_ptr_sysid
AND uom_conv.uom_ptr = item_uomconv.uom_ptr) NO-LOCK,
EACH product_group_minor WHERE (product_group_minor.system_id = item.pg_ptr_sysid
AND product_group_minor.pg_ptr = item.pg_ptr) NO-LOCK BREAK BY item.item:
DISPLAY
item.item LABEL "item" "|SEP|"
item.item_ptr LABEL "item_ptr" "|SEP|"
item.size LABEL "size" "|SEP|"
item.description LABEL "description" "|SEP|"
WITH WIDTH 250.
END.

Answer 1

Your construct is incorrect - the last "END" statement doesn't belong, unless you change the OPEN QUERY for a FOR EACH .....like so:
FOR EACH item
WHERE (item.system_id = '000000')
NO-LOCK,
EACH item_branch
WHERE (item_branch.system_id = item.system_id AND
item_branch.item_ptr = item.item_ptr)
NO-LOCK,
EACH item_uomconv
WHERE (item_uomconv.system_id = item.system_id AND
item_uomconv.item_ptr_sysid = item.system_id AND
item_uomconv.item_ptr = item.item_ptr)
NO-LOCK,
EACH uom_conv
WHERE (uom_conv.system_id = item_uomconv.uom_ptr_sysid AND
uom_conv.uom_ptr = item_uomconv.uom_ptr)
NO-LOCK,
EACH product_group_minor
WHERE (product_group_minor.system_id = item.pg_ptr_sysid AND
product_group_minor.pg_ptr = item.pg_ptr)
NO-LOCK
BREAK BY item.item:
DISPLAY
item.item LABEL "item"
"|SEP|" VIEW-AS TEXT
item.item_ptr LABEL "item_ptr"
"|SEP|" VIEW-AS TEXT
item.size LABEL "size"
"|SEP|" VIEW-AS TEXT
item.description LABEL "description"
"|SEP|" VIEW-AS TEXT
WITH WIDTH 250
DOWN
.
END.

Answer 2

I have taken the liberty of simplifying the example to use the well-known "sports2000" database. To have a dynamic query that uses BREAK-BY and joins your code should be more like this:
define query q1 for customer, order scrolling.
open query q1 for each customer no-lock, each order no-lock of customer break by order.shipDate.
get first q1.
do while available customer:
display customer.name order.shipDate.
get next q1.
end.
1) To use BREAK-BY in a dynamic query you need that query defined as SCROLLING.
2) The OPEN QUERY statement should end with a ".", not a ":".
3) You have to actually fetch the data prior to displaying it. GET FIRST and GET NEXT do that in my example.

Answer 3

Long time since I've done any progress, but I'd be tempted to remove the terminal colon on this line
AND product_group_minor.pg_ptr = item.pg_ptr) NO-LOCK BREAK BY item.item: