Need to remove tasks from Scheduled Tasks from NSIS installer while uninstalling - scheduled-tasks

Question

I have created an installer using NSIS. Now I am facing an issue like my application can create a scheduled task, but when I am uninstalling it, it is not removing/deleting tasks that I have created from my application, and they are still visible in Schedule Tasks. And I am scheduling an Autorun task every time.
How do I delete an Autorun task from Schedule Tasks when I am uninstalling it?

Answer 1

The best option is probably to just let your application do it; ExecWait '"$instdir\myapp.exe" /uninstalltask'
You could also execute at.exe/schtasks.exe with the nsExec plugin.
Calling the task scheduler API directly is complicated and there are two versions you need to deal with:
!include LogicLib.nsh
;V1:
!define CLSID_CTaskScheduler {148BD52A-A2AB-11CE-B11F-00AA00530503}
!define IID_ITaskScheduler {148BD527-A2AB-11CE-B11F-00AA00530503}
;V2:
!define CLSID_TaskScheduler {0F87369F-A4E5-4CFC-BD3E-73E6154572DD}
!define IID_ITaskService {2FABA4C7-4DA9-4013-9697-20CC3FD40F85}
RequestExecutionLevel Admin
!define MyTaskFolder "\"
!define MyTaskName "Test"
Section
System::Call "ole32::CoCreateInstance(g '${CLSID_TaskScheduler}', i 0, i 5, g '${IID_ITaskService}', *i.r1)i.r0"
${If} $0 = 0
!define VARIANTBYVALPARAM_EMPTY "i0xcccc0000,i0xcccccccc,i0xcccccccc,i0xcccccccc"
System::Call "$1->10(${VARIANTBYVALPARAM_EMPTY},${VARIANTBYVALPARAM_EMPTY},${VARIANTBYVALPARAM_EMPTY},${VARIANTBYVALPARAM_EMPTY})i.r0"
${If} $0 = 0
System::Call '$1->7(w "${MyTaskFolder}", *i.r2)i.r0' ; ITaskService::GetFolder
${If} $0 = 0
System::Call '$2->15(w "${MyTaskName}", i0)i.r0' ; ITaskFolder::DeleteTask
System::Call 'kernel32::FormatMessage(i 0x00001000|0x00000100|0x00000200,i0,i$0,i0,*i.r9,i0,i0)'
System::Call '*$9(&t${NSIS_MAX_STRLEN}.r3)'
System::Call 'kernel32::LocalFree(i$9)'
DetailPrint "ITaskFolder::DeleteTask HRESULT=$0 ($3)"
System::Call '$2->2()' ; ITaskFolder::Release
${EndIf}
${EndIf}
System::Call '$1->2()' ; ITaskService::Release
${EndIf}
${IfThen} $0 = 0 ${|} Goto done ${|}
System::Call "ole32::CoCreateInstance(g '${CLSID_CTaskScheduler}', i 0, i 5, g '${IID_ITaskScheduler}', *i.r1)i.r0"
${If} $0 = 0
System::Call '$1->7(w "${MyTaskName}")i.r0' ; ITaskScheduler::Delete
System::Call 'kernel32::FormatMessage(i 0x00001000|0x00000100|0x00000200,i0,i$0,i0,*i.r9,i0,i0)'
System::Call '*$9(&t${NSIS_MAX_STRLEN}.r3)'
System::Call 'kernel32::LocalFree(i$9)'
DetailPrint " ITaskScheduler::Delete HRESULT=$0 ($3)"
System::Call '$1->2()' ; ITaskScheduler::Release
${EndIf}
done:
SectionEnd