Drag and drop to desktop in LiveCode - drag-and-drop

Question

I'm working on an IDE extension. One of the first things I need to be able to do is drag an icon from my new tool panel out to
the open space and create a stack when released.
This is the code I have so far. The problem is that, when I release the drag, it pops the mouse back to the start position of
the drag and creates there rather then at the end position. I suspect that is because I am not dragging onto a destination object
since I am trying to make a new stack. How can I get the release point when its not over a LiveCode object?
on mouseDown
set the dragData["text"] to empty
end mouseDown
on dragStart
set the dragImage to the id of the target
end dragStart
on dragEnd
CreateNewDBStack("New Databse Stack", "Default.sdb")
end dragEnd
command CreateNewDBStack pNewStackName, pDBname
#create stack
create stack pNewStackName
put it into tTheNewStack
set the loc of tTheNewStack to the mouseloc
set the DBPath of tTheNewStack to pDBName
#create DBscript on stack
local tScript
put "global gDBConnectionID"&cr into tScript
put "command onPreOpenStack"&cr after tScript
put " library stack "&quote&"DatabaseLibrary.livecode"&quote&cr after tScript
put " put the DBPath of me into tDBPath"&cr after tScript
put " put databaseConnect(tDBPath) into gDBConnectionID" &cr after tScript
put "end onPreOpenStack" after tScript
set the script of tTheNewStack to tScript
end CreateNewDBStack

Answer 1

I don't think you're doing a real drag and drop, since you're not actually dragging an object from an app to another app (e.g. from your app to Finder or Windows Explorer). Therefore, you could use a different approach without drag and drop.
The following method creates a place holder stack. You could change the script to not delete the place holder stack and adjust its properties instead. I decided to delete the place holder stack and then run your script.
on mouseDown
set the rect of the templateStack to 0,0,100,100
set the decorations of the templateStack to "maximize,minimize,close"
set the backgroundColor of the templateStack to gray
set the blendLevel of the templateStack to 50
set the vis of the templateStack to true
set the name of the templateStack to "extPlace Holder"
set the loc of the templateStack to globalloc(the mouseLoc)
create stack
reset the templateStack
send "followMouse it" to me in 0 millisecs
end mouseDown
on followMouse theStack
put the mouseLoc into myLoc
if the mouse is down then
set the loc of theStack to globalLoc(myLoc)
send "followMouse theStack" to me in 20 millisecs
end if
end followMouse
on mouseRelease
put the mouseLoc into myLoc
if there is a stack "extPlace Holder" then delete stack "extPlace Holder"
createNewStack "New Database Stack","Default.sdb"
/*
if there is a stack "New Database Stack" then
set the loc of stack "New Database Stack" to myLoc
end if
*/
end mouseRelease
on mouseUp
put the mouseLoc into myLoc
if there is a stack "extPlace Holder" then delete stack "extPlace Holder"
end mouseUp
command createNewStack pNewStackName,pDBname
put globalLoc(the mouseloc) into myLoc
#create stack
set the vis of the templateStack to false
create stack pNewStackName
put it into tTheNewStack
set the loc of tTheNewStack to myLoc
set the DBPath of tTheNewStack to pDBName
#create DBscript on stack
local tScript
put "global gDBConnectionID"&cr into tScript
put "command onPreOpenStack"&cr after tScript
put " library stack "&quote&"DatabaseLibrary.livecode"&quote&cr after tScript
put " put the DBPath of me into tDBPath"&cr after tScript
put " put databaseConnect(tDBPath) into gDBConnectionID" &cr after tScript
put "end onPreOpenStack" after tScript
set the script of tTheNewStack to tScript
show tTheNewStack
reset the templateStack
end createNewStack

Answer 2

You can use the screenMouseLoc instead of the mouseLoc.
set the loc of tTheNewStack to the screenMouseLoc
The DB stack may jump to the new location, so creating the stack invisibly then setting the visible to true at the end of your script will avoid this.

Answer 3

I hope this code helps you to finish your extension.
What I'm doing is creating a stack which I put the image that I drag as a background. Something similar to what the LiveCode IDE does.
Important in the _deleteDragStack command find where CreateNewDBStack is called and pass it the parameters pNewStackName, pDBname.
local sDragStack
local sStackLoc
on mouseMove
if the mouse is up then
_deleteDragStack
else if the mouse is down and there is not a sDragStack then
local tTarget
put the target into tTarget
if word 1 of tTarget is "image" then
set the destroyStack of templateStack to true
set the windowShape of templateStack to (the id of tTarget)
set the backgroundPattern of templateStack to (the id of tTarget)
set the blendLevel of templateStack to 100
set the loc of templateStack to globalLoc(the mouseLoc)
create stack
put it into sDragStack
reset templateStack
end if
else if there is sDragStack then
put globalLoc( the mouseLoc) into sStackLoc
set the loc of sDragStack to sStackLoc
set the blendLevel of sDragStack to 25
end if
pass mouseMove
end mouseMove
on mouseUp
if there is sDragStack then _deleteDragStack
end mouseUp
on mouseRelease
if there is sDragStack then _deleteDragStack
end mouseRelease
private command _deleteDragStack
if there is sDragStack then
lock messages
close sDragStack
CreateNewDBStack "Untitled"&&(random(1000))---> pNewStackName, pDBname
delete local sDragStack
unlock messages
end if
end _deleteDragStack
command CreateNewDBStack pNewStackName, pDBname
local tTheNewStack
#create stack
create stack pNewStackName
put it into tTheNewStack
set the loc of tTheNewStack to sStackLoc
set the DBPath of tTheNewStack to pDBName
#create DBscript on stack
local tScript
put "global gDBConnectionID"&cr into tScript
put "command onPreOpenStack"&cr after tScript
put " library stack "&quote&"DatabaseLibrary.livecode"&quote&cr after tScript
put " put the DBPath of me into tDBPath"&cr after tScript
put " put databaseConnect(tDBPath) into gDBConnectionID" &cr after tScript
put "end onPreOpenStack" after tScript
set the script of tTheNewStack to tScript
end CreateNewDBStack