how to set up readonly property in excel vba class module - class

Question

I have the following in a class module called clsAgent:
Option Explicit
Const AgentEmailCol = 9
Private pAgentSheetName As String
Private pIDRange As Range
Private pAgentID As String
Private pAgentEmail As String
Public Property Get AgentSheetName() As String
AgentSheetName = pAgentSheetName
End Property
Public Property Let AgentSheetName(AgentSheetName As String)
pAgentSheetName = AgentSheetName
End Property
Public Property Get IDRange() As Range
Set IDRange = pIDRange
End Property
Public Property Set IDRange(IDRange As Range)
Set pIDRange = IDRange
End Property
Public Property Get AgentID() As String
AgentID = pAgentID
End Property
Public Property Let AgentID(AgentID As String)
pAgentID = AgentID
End Property
Public Property Get AgentEmail() As String
AgentEmail = WorksheetFunction.VLookup(Me.AgentID, Me.IDRange, AgentEmailCol, False)
End Property
in a class called clsWorkingRange I have:
Option Explicit
Private pSheetName As String
Private pColNum As Integer
Private pTargetRange As Range
Public Property Get SheetName() As String
SheetName = pSheetName
End Property
Public Property Let SheetName(SheetName As String)
pSheetName = SheetName
End Property
Public Property Get ColNum() As Integer
ColNum = pColNum
End Property
Public Property Let ColNum(ColNum As Integer)
pColNum = ColNum
End Property
Public Property Get TargetRange() As Range
Set TargetRange = pTargetRange
End Property
Public Property Set TargetRange(TargetRange As Range)
Set pTargetRange = TargetRange
End Property
Private Function Get_Rows_Generic(work_sheet_get As String, column_num As Integer)
'worksheet is the name of a sheet in the form of a string
Dim ws As Worksheet: Set ws = Worksheets(work_sheet_get)
Dim rows_count As Long: rows_count = ws.Cells(rows.Count, column_num).End(xlUp).Row
Get_Rows_Generic = rows_count
End Function
Public Function set_range(sheet_name As String, col1 As Integer) As Range
' returns the range of a given column using all the rows in a street
Dim rows1 As Long
rows1 = Get_Rows_Generic(sheet_name, 1)
Dim range1 As Range ' range of first search
With Worksheets(sheet_name)
Set range1 = .Range(.Cells(1, col1), .Cells(rows1, col1)) ' set the range being searched first
End With
Set set_range = range1
End Function
I have a class called clsWorkingSheet:
Option Explicit
Private pSheetName As String
Private pSheet As Worksheet
Public Property Get SheetName() As String
SheetName = pSheetName
End Property
Public Property Let SheetName(SheetName As String)
pSheetName = SheetName
End Property
Public Property Get Sheet() As Worksheet
Set Sheet = pSheet
End Property
Public Property Set Sheet(Sheet As Worksheet)
Set pSheet = Sheet
End Property
In a separate module I have the following:
Sub test_agent_class()
Dim agent_Sheet As clsWorkingSheet
Set agent_Sheet = New clsWorkingSheet
agent_Sheet.SheetName = "agentsFullOutput.csv"
Set agent_Sheet.Sheet = Worksheets(agent_Sheet.SheetName)
Dim agent_Range As clsWorkingRange
Set agent_Range = New clsWorkingRange
Set agent_Range.TargetRange = agent_Range.set_range(agent_Sheet.SheetName, 1)
Dim agent_Individual As clsAgent
Set agent_Individual = New clsAgent
Set agent_Individual.IDRange = agent_Range.TargetRange
Debug.Print agent_Individual.IDRange.Address
agent_Individual.AgentID = "ObjectID(52d56512763f4a1c608b4753)"
Debug.Print agent_Individual.AgentID
Debug.Print agent_Individual.AgentEmail
end sub
I get the following error: Run-time error '1004': Method 'AgentEmail' of object 'clsAgent' failed
¸

Answer 1

Everything here looks fine to me. I've tested it myself and it worked as I believe you expect it should.
The only thing I see going wrong is if your agent_Range.TargetRange has less than 9 columns, since that's what you are looking up in your vlookup with Const AgentEmailCol = 9
Based on your updated question/code:
It looks like this bit in your clsWorkingRange.set_range() function only returns a range with a single column. You can't do a vlookup that fetches from the 9th column in a 1 column sized range. You'll need to make sure that agent_Range.TargetRange is set to something that is at least 9 columns wide. Check the output of your Debug.Print agent_Individual.IDRange.Address to confirm.