AutoHotKey macro scripting to open Outlook and create appointment - macros

Question

I am new to AutoHotKey, I think it's a great tool for shortcuts.
I would like to create a macro shortcut when I use a HotKey to create new meeting using Outlook that will pre-populate the to email address to a couple people and set the subject and location to what i want.
Any help would be appreciated.
thanks
Kishen

Answer 1

It is not particularly robust or elegant but the code below works well on my machine. Have outlook running open to inbox without other outlook windows present for testing. Pressing 'window + u' will first look for an approximate window match (you can also use ahk_class) and send keystrokes to emulate creating a new meeting. You'll need to change 'outlook preview' to something else if you are not yet using outlook 2016.
edit: based on ahkcoder's suggestion, I tried the COM Object approach and was able to get it to work for a meeting request. This is working on Outlook 2016. Keep outlook open and hit 'windows + y' to make the new meeting request using the COM solution. Here COM has less screen updating and appears as though it would be more reliable/robust in the long-term. I'd feel more comfortable using it in a production setting.
#u::
Settitlematchmode, 2
Winactivate, Outlook Preview
WinWaitActive, Outlook Preview
Sleep 60
SendInput {altdown}h
Sleep 60
SendInput i
Sleep 60
SendInput e
Sleep 60
SendInput {altup}
Sleep 60
Winactivate, Untitled - Meeting
WinWaitActive, Untitled - Meeting
Sleep 60
SendInput myemailaddress#outlook.com;someotheremail#outlook.com
Sleep 60
SendInput {space 2}
Sleep 60
SendInput {tab}
Sleep 60
SendInput mysubject
Sleep 60
SendInput {tab}
Sleep 60
SendInput mylocation
return
#y::
app := ComObjActive("Outlook.Application")
olAppointmentItem := 1 ;1 is the olItemType Enumeration for Appointment
olMeeting := 1 ; olMeeting is an appointment so initialize to 1 here also.
MailItem := app.CreateItem(olAppointmentItem)
MailItem.MeetingStatus := olMeeting
MailItem.Subject := "mysubject"
MailItem.Recipients.Add("firstemail#gmail.com")
MailItem.Recipients.Add("secondemail#gmail.com")
MailItem.Location := "mylocation"
MailItem.Display
return

Answer 2

Welcome to the wonderful world of easy Windows Automation using AutoHotkey! You can certainly get a lot of tasks done through simple, straight forward, scripts like the one Coldrainwater posted.
But just know that there are some advanced features that AutoHotkey has implemented over the years, among the most notable are COM Objects, DLL Function Calls, Object Oriented Programming.
When you've gotten through the help file and brushed up on the basics, perhaps you'll look into making use of Outlook COM Object Reference here:
http://www.autohotkey.com/board/topic/71335-mickers-outlook-com-msdn-for-ahk-l/
Best of luck to you!