Should Exception::Class objects evaluate to false in boolean context - perl

Question

I'm trying Exception::Class for the first time and something that surprised me is that Exception::Class objects evaluate to true when returned from a function. Shouldn't the default be the opposite.
I know I can change this with overload but I am wondering if it's a good idea
sub gethtml{
return MyException->new( error => 'some error' );
}
my $response = &gethtml
if($response){
#do something with the html
}
else{
#something went wrong check if it's an exception object
}

Answer 1

You're confusing exceptions with returning a false value to indicate an error.
Part of the point of exceptions is that they provide their own channel to indicate error. This leaves return free to only return valid values. There's no need to check for false vs defined, or special objects, or do any per-function call error checking at all. It's all caught and dealt with at the end of the block.
If you return an exception object it defeats the point; they're not exceptions, they're just error codes.
To take advantage of exceptions, the code in your example should be written like this:
sub get_html {
...try to get the html...
return $html if defined $html;
MyException->throw( error => 'some error' );
}
eval {
my $html = get_html;
# do something with $html;
}
if ( my $e = Exception::Class->caught() ) {
...deal with the error...
}
This can be made a bit prettier with Try::Tiny.
This makes more sense when you have to do a lot of things which might error, such as a bunch of file, network or database operations. Look into modules such as autodie and Path::Tiny for how that works.

Answer 2

You should not create one with new and return it. They have a throw method that acts as constructor and die automatically.
use strict;
use warnings;
use Exception::Class qw( InputException HTTPException );
use Try::Tiny;
sub get_html {
my ($url) = #_;
# input validation
InputException->throw(error => 'no URL') unless $url;
my $res = $ua->get($url);
if ($res->is_success) {
# do more stuff with $res;
} else {
HTTPException->throw( error => 'request failed' );
}
}
# ... later
my $url;
try {
get_html($url);
} catch {
# handle the error which is in $_
if ( $_->isa('InputException') ) {
print "You need to supply a URL";
} elsif ( $_->isa('HTTPException') ) {
print "Could not fetch the HTML because the HTTP request failed.\n";
print "But I am not telling you why.";
}
}
You can then go and catch them (use Try::Tiny for that) or simply wrap it in an eval. But basically those exceptions are simple objects. They are intended as the return value of die and get thrown around, so there is no need to return them anywhere.
Once the program dies, all the scopes on the call stack are exited forcefully until you end up in an eval block (which is what catch does). There, you can handle the error. And since that error is an object, you can do fancy stuff with it.
+--------------------------------------------------------------------+
| sub { |
| +----------------------------------------------------------------+ |
| | if () { | |
| | +------------------------------------------------------------+ | |
| | | foo:: sub { | | |
| | | +--------------------------------------------------------+ | | |
| | | | catch { | | | |
| | | | +----------------------------------------------------+ | | | |
| | | | | doo_stuff:: sub { | | | | |
| | | | | +------------------------------------------------+ | | | | |
| | | | | | | | | | | |
| | | | | | MyException->throw ==> die $obj +---------------------------------+
| | | | | | do_more_stuff(); # never executed | | | | | | |
| | | | | | | | | | | | |
| | | | | +------------------------------------------------+ | | | | | |
| | | | +----------------------------------------------------+ | | | | |
| | | | | | | | |
| | | | handle_exception_in_catch($_) <---------------------------------+
| | | | # ( in Try::Tiny the exception ends up in $_ ) | | | |
| | | | | | | |
| | | +--------------------------------------------------------+ | | |
| | +------------------------------------------------------------+ | |
| +----------------------------------------------------------------+ |
+--------------------------------------------------------------------+
Also see the Exception::Class docs.
If you mix exceptions and regular die or Carp croak calls, you will have to do a lot of checking if stuff is blessed before using ->isa. Safe::Isa comes in handy here.
use strict;
use warnings;
use Exception::Class qw( InputException HTTPException );
use Try::Tiny;
use Safe::Isa;
sub get_html {
my ($url) = #_;
# input validation
InputException->throw(error => 'no URL') unless $url;
my $res = $ua->get($url);
if ($res->is_success) {
# do more stuff with $res;
die "There is no answer in this HTML" if $res->decoded_content !~ m/42/;
} else {
HTTPException->throw( error => 'request failed' );
}
}
With this code, the $_->isa('...') would blow up, because in case of the die call, $_ is not an object and you cannot call the method isa on an unblessed reference (or non-reference). Safe::Isa provides a $_isa, which checks for that first and otherwise just returns false.
my $url;
try {
get_html($url);
} catch {
# handle the error which is in $_
if ( $_->$_isa('InputException') ) {
print "You need to supply a URL";
} elsif ( $_->$_isa('HTTPException') ) {
print "Could not fetch the HTML because the HTTP request failed.\n";
print "But I am not telling you why.";
}
}
For details on how that works, see mst's talk You did what?