How to calculate "midpoint date" by group in Stata? - date

Question

I have a dataset with two variables: journalistName, articleDate
For each journalist (group), I want to create a variable that chronologically categorizes the articles into 1 for "first half" and 2 for "second half".
For example, if a journalist wrote 4 articles, I want first two articles categorized as 1.
If he wrote 5 articles, I want first three articles categorized as 1.
One possibility I thought of is to calculate the midpoint date and then use if condition (gen cat1 = 1 if midpoint > startdate) but I dont know how to generate such midpoint in Stata.

Answer 1

Per your description of which articles to categorize as 1, you're looking for the midpoint of the number of articles rather than the midpoint of the date range.
One solution is to use by group processing, _n, and _N:
gen cat = 2
bysort author (date): replace cat = 1 if _n <= ceil(_N/2)
This sorts by author and date, and then assigns cat = 1 to observations within each group of author where the current observation (_n) number is less than or equal to the median observation (ceil(_N/2)).
Note that you need a numeric (rather than string) date for the sort to work properly. Also, in my opinion, cat = {1,2} is less intuitive than something like firsthalf = {0,1}. Either way, labeling the values (help label) would aid clarity.
For more information, see help by and this article.
Finally, the method in action:
clear all
input str10 author str10 datestr
"Alex" "09may2015"
"Alex" "06apr2015"
"Alex" "15jul2014"
"Alex" "19aug2013"
"Alex" "03mar2009"
"Betty" "09may2015"
"Betty" "06apr2015"
"Betty" "15jul2014"
"Betty" "19aug2013"
end
gen date = daily(datestr, "DMY")
format date %td
gen cat = 2
bysort author (date): replace cat = 1 if _n <= ceil(_N/2)
list , sepby(author) noobs
and the result
+--------------------------------------+
| author datestr date cat |
|--------------------------------------|
| Alex 03mar2009 03mar2009 1 |
| Alex 19aug2013 19aug2013 1 |
| Alex 15jul2014 15jul2014 1 |
| Alex 06apr2015 06apr2015 2 |
| Alex 09may2015 09may2015 2 |
|--------------------------------------|
| Betty 19aug2013 19aug2013 1 |
| Betty 15jul2014 15jul2014 1 |
| Betty 06apr2015 06apr2015 2 |
| Betty 09may2015 09may2015 2 |
+--------------------------------------+
If you are indeed seeking to calculate the midpoint date, you can do so using the same general principle:
bysort author (date): gen beforemiddate = date <= ceil((date[_N] + date[1]) / 2)
Also, to find the last date in the "pre-midpoint" period, you can use the same principles:
bysort author cat (date): gen lastdate = date[_N] if cat == 1
by author: replace lastdate = lastdate[_n-1] if missing(lastdate)
format lastdate %td
or an egen function with a logical test included gets the job done a bit faster:
egen lastdate = max(date * (cat == 1)) , by(author)
format lastdate %td