Sum only first occurrence on a node in XSLT - group-by

Question

I'm running into a bit of a challenge. I'm working on summing the values contained in a child node without using a recursive template. I have a source similar to this:
<root>
<entry>
<recordID>001</recordID>
<amount>500</amount>
</entry>
<entry>
<recordID>001</recordID>
<amount>200</amount>
</entry>
<entry>
<recordID>002</recordID>
<amount>500</amount>
</entry>
<entry>
<recordID>003</recordID>
<amount>400</amount>
</entry>
<entry>
<recordID>004</recordID>
<amount>100</amount>
</entry>
</root>
What I'm trying to do is ONLY sum the FIRST occurrence of a recordID and count those nodes. I.e. I do not want to include the 2nd node. So the desired output would be
Record Count: 4
Total Amount: 1500
I've attempted to this, but it only returns 0. I'm not sure if it's because you can only reference siblings inside of a for each or not. but here was my first attempt:
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
<xsl:template match='root'>
<xsl:value-of select='"Record Count: "'/>
<xsl:value-of select='count(entry[recordID != following-sibling::recordID])'/>
<xsl:value-of select='"Total Amount: "'/>
<xsl:value-of select='sum(entry[recordID != following-sibling::recordID]/amount)'/>
</xsl:template>
</xsl:stylesheet>
But this just returned 0. I also tried this, but it was also unsuccessful
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
<xsl:template match='root'>
<xsl:value-of select='"Record Count: "'/>
<xsl:for-each-group select='entry' group-by='.[recordID != following-sibling::recordID]'>
<xsl:value-of select='count(current-group())'/>
</xsl:for-each-group>
<xsl:value-of select='"Total Amount: "'/>
<xsl:for-each-group select='entry' group-by='.[recordID != following-sibling::recordID]'>
<xsl:value-of select='sum(current-group()/amount)'/>
</xsl:for-each-group>
</xsl:template>
</xsl:stylesheet>
If anyone could offer some insight into how I could accomplish this, or corrections in my current code - I would greatly appreciate it!
Thanks in advance for any feedback

Answer 1

Here is an XSLT 2.0 example using Muechian grouping (with a slight adaption of simply using is instead of generate-id as XSLT 2.0 is assumed):
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
<xsl:key name="entry-by-id" match="entry" use="recordID"/>
<xsl:variable name="first-records" select="root/entry[. is key('entry-by-id', recordID)[1]]"/>
<xsl:template match='root'>
<xsl:value-of select='"Record Count: "'/>
<xsl:value-of select='count($first-records)'/>
<xsl:value-of select='"Total Amount: "'/>
<xsl:value-of select='sum($first-records/amount)'/>
</xsl:template>
</xsl:stylesheet>
With for-each-group you can use an approach like
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
<xsl:template match='root'>
<xsl:variable name="first-entries" as="element(entry)*">
<xsl:for-each-group select='entry' group-by='recordID'>
<xsl:copy-of select='.'/>
</xsl:for-each-group>
</xsl:variable>
<xsl:value-of select='"Record Count: "'/>
<xsl:value-of select='count($first-entries)'/>
<xsl:value-of select='"Total Amount: "'/>
<xsl:value-of select='sum($first-entries/amount)'/>
</xsl:template>
</xsl:stylesheet>

Answer 2

I've updated your first XSLT:
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
<xsl:template match='root'>
<xsl:value-of select='"Record Count: "'/>
<xsl:value-of select='count(entry[not(recordID = preceding::entry/recordID)])'/>
<xsl:value-of select='"Total Amount: "'/>
<xsl:value-of select='sum(entry[not(recordID = preceding::entry/recordID)]/amount)'/>
</xsl:template>
</xsl:stylesheet>
Your XPATH, entry[recordID != following-sibling::recordID] won't give you the distinct entry elements(distinct by their recordIDs), but my XPATH will.
Reason,
recordID != following-sibling::recordID
means that you are checking if any of the following-sibling recordIDs have a different value than the current recordID(at the first place, there are no recordID siblings to any of the recordIDs in your input).
On the other hand when the xpath is:
entry[not(recordID = preceding::entry/recordID)]
The current recordID is matched with any of the preceding recordIDs, and the ones that match are ignored. This way only entry elements are grouped by recordID.
I suggest you to read about how != operator works against not():
a != (b,c,d) and not(a = (b,c,d)) are not same.