Create dictionary from table using hash object - hash

Question

I'm sure it's an easy task, but I'm still neophyte at SAS, so I have some problems :(.
Consider, I have some data set Table with column Column $24 (length is important). And I want to create a data set HashTable with only one column Key $11, where Key consists of those unique values of Column, which length equals 11.
So, I'm trying to use a hash object, but I feel I'm doing something wrong :).
data _null_;
length Key $11;
set Table end = _end;
if _N_ = 1 then do;
declare hash h();
h.defineKey('Key');
h.defineDone();
end;
if length(Column) = 11 then
rc = h.add(Key: Column);
if _end then
rc = h.output(dataset: 'HashTable');
run;
When I submit program I get errors:
7904 rc = h.add(Key: Column);
ERROR: Incorrect number of data entries specified at line 7904 column 14.
ERROR: DATA STEP Component Object failure. Aborted during the EXECUTION phase.

Answer 1

This issue has been identified by Paul Dorfman in 2007 on SAS-L, Paul Dorfman on Hash error
Simply put, ADD() method is expecting either both 'key' and 'data' or none (which implies both). The following also works, even you 'data' hasn't been defined explicitly.
data _null_ ;
length key $ 5;
set sashelp.shoes end = _end ;
if _N_ = 1 then do ;
declare hash h() ;
h.defineKey('key') ;
h.defineDone() ;
end ;
if length(Subsidiary)=5 then rc=h.add(key:subsidiary, data:Subsidiary) ;
if _end then h.output(dataset: 'HashTable') ;
run ;

Answer 2

Your code looks pretty good to me. The one mistake I notice is that your statements:
if length(Column) = 11 then;
rc = h.add(Key: Column);
if _end then;
rc = h.output(dataset: 'HashTable');
have an extra semicolon. There should be no semicolon after the then. As written, the h.add and h.output are executed unconditionally.
Here is an example using sashelp.shoes along the lines of your examole:
data _null_ ;
set sashelp.shoes end = _end ;
if _N_ = 1 then do ;
declare hash h() ;
h.defineKey('Subsidiary') ;
h.defineDone() ;
end ;
if length(Subsidiary)=5 then rc=h.add() ;
if _end then h.output(dataset: 'HashTable') ;
run ;
Which returns:
115 data _null_ ;
116 set HashTable ;
117 put (_all_)(=) ;
118 run ;
Subsidiary=Tokyo
Subsidiary=Cairo
Subsidiary=Paris
Subsidiary=Seoul
Subsidiary=Dubai
NOTE: There were 5 observations read from the data set WORK.HASHTABLE.

Answer 3

A mistake was stupid, as I expected:)
The right code (I hope):
data _null_;
length Key $11;
set Table end = _end;
if _N_ = 1 then do;
declare hash h();
h.defineKey('Key');
h.defineDone();
end;
if length(Column) = 11 then do;
Key = Column;
rc = h.add();
end;
if _end then
rc = h.output(dataset: 'HashTable');
run;