Cassandra: how to search key columns with DECIMAL? - select

Question

I understand Cassandra is designed for String based Key/Value pair.
I have a need to have Cassandra table with Decimal keys. Is there anyway to search the keys with range of numeric values. Like keys between 3 and 6 (inclusive)??.
Sample Key Column
1
3.3
6.345
9
10
2.5

Answer 1

Let's try this out. Assume a simple table with a decimal key, and a text value.
CREATE TABLE decimalRangePK (dec decimal, value text, PRIMARY KEY (dec));
In this case, dec is my partition key. And it is my only key, as there is not a clustering key present. After INSERTing some data, here is what I have:
aploetz#cqlsh:stackoverflow> SELECT * FROM decimalrangepk ;
dec | value
------+-------
2.5 | ghi
6.35 | abc
9 | def
3.2 | 3.2
1 | 1
3.3 | 3.3
10 | ten
(7 rows)
So I assume that you are trying a range query on your partition key, like this:
aploetz#cqlsh:stackoverflow> SELECT * FROM decimalrangeck WHERE dec>=3.3 AND dec<=9;
InvalidRequest: code=2200 [Invalid query] message="Cannot execute this query as it might involve data filtering and thus may have unpredictable performance. If you want to execute this query despite the performance unpredictability, use ALLOW FILTERING"
As you can see, this doesn't work. Cassandra cannot execute range query on a partition key. However, because clustering keys are used enforce on-disk sort order (within a partition key) you can execute a range query on a clustering key.
In this next example, I'll try this again. But this time I will partition my data by date, like this:
CREATE TABLE decimalRangeCK (dateBucket text, dec decimal, value text,
PRIMARY KEY (dateBucket,dec));
After inserting some rows, I'll query the table and it will look slightly different:
aploetz#cqlsh:stackoverflow> SELECT * FROM decimalrangeck ;
datebucket | dec | value
------------+------+-------
20151108 | 1 | 1
20151108 | 3.2 | 3.2
20151110 | 2.5 | ghi
20151110 | 10 | ten
20151109 | 1 | 1
20151109 | 3.3 | 3.3
20151109 | 6.35 | abc
20151109 | 9 | def
(8 rows)
Now I can run a range query on dec, as long as I also provide a partition key:
aploetz#cqlsh:stackoverflow> SELECT * FROM decimalrangeck WHERE datebucket='20151109'
AND dec>=3.3 AND dec<=9;
datebucket | dec | value
------------+------+-------
20151109 | 3.3 | 3.3
20151109 | 6.35 | abc
20151109 | 9 | def
(3 rows)
As you can see, picking a good partition key is very important. High cardinality, unique partition keys are great for data distribution, but don't really give you a whole lot of query flexibility.