Converting a text file with one column to multiple column [closed] - powershell

Question

Closed. This question needs to be more focused. It is not currently accepting answers.
Want to improve this question? Update the question so it focuses on one problem only by editing this post.
Closed 7 years ago.
Improve this question
I have a file with data in one column format. I need to use this file as an input file and the output file should be in a multi column format. I need help with a script that will do the conversion. It does not matter PowerShell or batch.
Input file content:input.txt
store1:
apple
orange
peach
THE END
store2:
Tree
Park
Pond
Bird
THE END
store3:
Building
Road
peach
store
Grocery
THE END
The output file should be:
store1:,store2:,store3:
apple, Tree, Building
orange, Park, Road
peach, Pond, peach
, Bird, store
, , Grocery

Answer 1

i know this is a gimmie, but i took it as a learning opportunity for myself, and since i have the code maybe someone else can learn from it
$text = gc C:\temp\input.txt
$groups = ($text | out-string) -split 'the end' | ? {$_ -notmatch '^(?:\s+)?$'}
$columns = $groups | % {$_.trim().split("`n")[0]}
$rows = $groups | % {$_.trim().Split("`n").count - 2} | sort -desc | select -f 1
$result = 0..$rows | % {
$row = $_
$obj = New-Object psobject
0..$($columns.Count-1) | % {
$column = $columns[$_]
$store = $groups[$_].trim().split("`n")
$item = $store[$row+1]
$obj | Add-Member -MemberType NoteProperty -Name $column.trim() -Value $(if ($item) {$item.trim()})
}
$obj
}
$result | epcsv C:\temp\input.csv -NoTypeInformation

Answer 2

Here is a pure batch-file solution:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
rem Define global settings here:
set "INFILE=input.txt"
set "OUTFILE=output.txt"
set "HEAD=^store[1-9][0-9]*:$"
set "FOOT=^THE END$"
set "DELIM=,"
set /A "COL=0, ROW=0, MAX=0"
for /F "delims=" %%L in ('
findstr /N /R "^" "%INFILE%"
') do (
set "LINE=%%L"
setlocal EnableDelayedExpansion
set "LINE=!LINE:*:=!"
if defined HEAD (
if !COL! EQU 0 set /A "ROW=-1"
cmd /V /C "echo^(!LINE!"| > nul findstr /R /C:"%HEAD%" ^
&& if !ROW! LSS 0 set /A "COL+=1, ROW=0"
if defined FOOT (
cmd /V /C "echo^(!LINE!"| > nul findstr /R /C:"%FOOT%" ^
&& set /A "ROW=-1" || if !COL! GTR 0 if !ROW! GEQ 0 set /A "ROW+=1"
) else (
if !COL! GTR 0 set /A "ROW+=1"
)
) else (
if defined FOOT (
if !ROW! EQU 0 set /A "COL+=1"
cmd /V /C "echo^(!LINE!"| > nul findstr /R /C:"%FOOT%" ^
&& set /A "ROW=0" || set /A "ROW+=1"
) else (
if !COL! EQU 0 set /A "COL=1"
if defined LINE (
set /A "ROW+=1"
) else (
if !ROW! GTR 0 set /A "COL+=1"
set /A "ROW=0"
)
)
)
if !MAX! LSS !ROW! set /A "MAX=!ROW!"
for /F "tokens=1-3 delims=;" %%I in ("!COL!;!ROW!;!MAX!") do (
endlocal
if %%I GTR 0 if %%J GTR 0 (
set "COLLECT[%%I_%%J]=%%L"
)
set /A "COL=%%I, ROW=%%J, MAX=%%K"
)
)
setlocal EnableDelayedExpansion
> "%OUTFILE%" (
for /L %%J in (1,1,%MAX%) do (
set "LINE="
for /L %%I in (1,1,%COL%) do (
if %%I GTR 1 set "LINE=!LINE!!DELIM!"
if defined COLLECT[%%I_%%J] (
set "LINE=!LINE!!COLLECT[%%I_%%J]:*:=!"
)
)
echo(!LINE!
)
)
endlocal
endlocal
exit /B
Basically this script collects the data in an array-like variable COLLECT[COL_ROW], where COL and ROW denote the column and row indexes, respectively. The code consists of two loops, where the first one walks through the given input file and assigns the line texts to the related array elements. The predefined header and footer strings (or, if both are not provided, any empty lines) control determination of the applicable COL and ROW indexes. MAX holds the greatest row index ROW, because the blocks of data might be of different size, for later padding. The second loop enumerates the collected data array, builds a line of text per each column and writes them to the specified output file.
The code section at the beginning marked with a remark rem defines the global settings of the script, like the input file (INFILE), the output file (OUTFILE), the header and the footer (HEAD and FOOT, respectively; both findstr-compatible regular expressions; either or both of them can be empty) and the delimiter (DELIM).
This approach has got 4 modes:
both header and footer are non-empty:
data is collected beginning at the first header string;
another header appearing after a footer starts a new data column;
everything between a footer and the next header is ignored;
a header appearing after another one and before a footer is treated as a normal field;
header texts are included in the returned data, footer texts are not;
empty lines are kept, meaning they result in an empty field;
header is non-empty but footer is empty:
data is collected beginning at the first header string;
another header starts a new data column;
header texts are included in the returned data;
empty lines are kept, meaning they result in an empty field;
footer is non-empty but header is empty:
data is collected beginning at the very first line;
a footer starts a new data column;
footer texts are not included in the returned data;
empty lines are kept, meaning they result in an empty field;
both header and footer are empty:
data is collected beginning at the first non-empty line;
a block of one or more consecutive empty lines starts a new data column;
empty lines are not included in the returned data;
Note:
Although the question lacks of information and attempts of or research by the poster, I decided to answer it, because the task at hand is a quite interesting challenge being solved with a batch-file.
EDIT: The code below is a solution from user Aacini (not from aschipfl) posted here after the original poster of this answer give me his kindly permission. I was forced to do this because the question is closed and I really wanted to post my code!
#echo off
setlocal EnableDelayedExpansion
rem Initialize data for first store
set /A max=0, lines=0, store=0
for /F "delims=" %%a in (input.txt) do (
if "%%a" neq "THE END" (
rem Process the next line of this store
set /A lines+=1
for %%l in (!lines!) do (
if not defined line[%%l] (
rem This store have more lines than previous ones: initialize new line
for /L %%i in (1,1,!store!) do set "line[%%l]=!line[%%l]! ,"
)
rem Append new data to this line
set "line[%%l]=!line[%%l]!%%a,"
)
) else (
rem This store ends: get the maximum number of lines
if !lines! gtr !max! (
set "max=!lines!"
) else (
rem Enlarge the additional lines of previous stores, if any
set /A lines+=1
for /L %%i in (!lines!,1,!max!) do set "line[%%i]=!line[%%i]! ,"
)
rem Pass to next store
set /A lines=0, store+=1
)
)
rem Output all result lines
(for /L %%i in (1,1,%max%) do echo !line[%%i]:~0,-1!) > output.txt
Output:
store1:,store2:,store3:
apple, Tree, Building
orange, Park, Road
peach, Pond, peach
, Bird, store
, , Grocery

Answer 3

You can pipe a text file into this PowerShell script. It uses PowerShell's dialect of CSV (which includes quote chars).
Begin {
# corresponds to (untransposed) records
$records = #()
# the current record
$this_record = #()
# maximum fields of any (untransposed) record
$max_fields = 0
}
Process {
If ($_ -eq "THE END") {
# Append the record to the array.
$records += ,$this_record
# Count the maximum number of fields (this will be the number of
# records when the data is transposed).
If ($this_record.Length -gt $max_fields) {
$max_fields = $this_record.Length
}
$this_record = #()
} ElseIf ($_.Trim() -eq "") {
# Ignore blank lines.
} Else {
# Append the field to the current record.
$this_record += $_
}
}
End {
# Transpose the fields
$objects = #()
For ($col=0; $col -lt $max_fields; $col+=1) {
# ConvertTo-CSV gets object properties. It doesn't implicitly
# operate on arrays the way we'd prefer.
$obj = New-Object PSCustomObject
For ($row=0; $row -lt $records.Length; $row+=1) {
# Create property names that sort lexically (zero-padded numbers).
$obj | Add-Member -MemberType NoteProperty `
-Name ("{00000}" -f $row) `
-Value $records[$row][$col]
}
$objects += $obj
}
# Convert to CSV, throw away the header
$objects | ConvertTo-CSV -NoTypeInformation | Select-Object -Skip 1
}
E.g. PowerShell -NoProfile -ExecutionPolicy Bypass -File xpose.ps1 < input.txt produces:
"store1:","store2:","store3:"
"apple","Tree","Building"
"orange","Park","Road"
"peach","Pond","peach"
,"Bird","store"
,,"Grocery"

Answer 4

Here's some code to help you out. Study this!
appendcolumn.bat
#echo off
set i=1
for /f "tokens=*" %%x in ('more') do (
call :app !i! %%x
set /a i += 1
)
exit /b
:app
set line%1=!line%1!,%2
exit /b