ERROR: Connection Closed Gracefully - email

Question

I have tried the below code for sending the mail, but it shows connection closed gracefully error. I have tried 587 and 465 port also. Authentication also raise the error for "5.7.0 Must issue a STARTTLS command first. q27sm64805279pfi.83 - gsmtp".
uses
IdSMTP, IdMessage, IdEMailAddress;
procedure SendSimpleMail;
var
IdSMTP: TIdSMTP;
IdMessage: TIdMessage;
IdEmailAddressItem: TIdEmailAddressItem;
begin
IdSMTP := TIdSMTP.Create(nil);
try
IdSMTP.Host := 'smtp.gmail.com';
IdSMTP.Port := 25; // or 587 //or 465
IdSMTP.AuthType := satDefault;
IdSMTP.Username := 'username#gmail.com';
IdSMTP.Password := 'password';
IdSMTP.Connect;
if IdSMTP.Authenticate then
begin
IdMessage := TIdMessage.Create(nil);
try
IdMessage.From.Name := 'User Name';
IdMessage.From.Address := 'username#gmail.com';
IdMessage.Subject := 'E-mail subject';
IdMessage.Body.Add('E-mail body.');
IdEmailAddressItem := IdMessage.Recipients.Add;
IdEmailAddressItem.Address := 'recipient#email.com';
IdSMTP.Send(IdMessage);
finally
IdMessage.Free;
end;
end;
IdSMTP.Disconnect;
finally
IdSMTP.Free;
end;
end;

Answer 1

To use STARTTLS, you need to
assign an SSLIOHandler component, such as TIdSSLIOHandlerSocketOpenSSL, to the TIdSMTP.IOHandler property. You will have to deploy the OpenSSL DLLs with your app, if not already installed on the target machine that will be running your app.
set the TIdSMTP.UseTLS property to utUseExplicitTLS to enable STARTTLS handling. Make sure TIdSMTP.UseEHLO is true (it is by default) so TIdSMTP can discover whether the server supports STARTTLS.
connect to port 587.
Try this:
uses
IdSMTP, IdMessage, IdEMailAddress, IdSSLOpenSSL;
procedure SendSimpleMail;
var
IdSMTP: TIdSMTP;
IdMessage: TIdMessage;
IdEmailAddressItem: TIdEmailAddressItem;
IdSSL: TIdSSLIOHandlerSocketOpenSSL;
begin
IdSMTP := TIdSMTP.Create(nil);
try
IdSSL := TIdSSLIOHandlerSocketOpenSSL.Create(IdSMTP);
IdSMTP.IOHandler := IdSSL;
IdSMTP.UseTLS := utUseExplicitTLS;
IdSMTP.Host := 'smtp.gmail.com';
IdSMTP.Port := 587;
IdSMTP.AuthType := satDefault;
IdSMTP.Username := 'username#gmail.com';
IdSMTP.Password := 'password';
IdSMTP.Connect;
if IdSMTP.Authenticate then
begin
IdMessage := TIdMessage.Create(nil);
try
IdMessage.From.Name := 'User Name';
IdMessage.From.Address := 'username#gmail.com';
IdMessage.Subject := 'E-mail subject';
IdMessage.Body.Add('E-mail body.');
IdEmailAddressItem := IdMessage.Recipients.Add;
IdEmailAddressItem.Address := 'recipient#email.com';
IdSMTP.Send(IdMessage);
finally
IdMessage.Free;
end;
end;
IdSMTP.Disconnect;
finally
IdSMTP.Free;
end;
end;
Update: the code above is meant for Indy 10. If you are using Indy 9 instead, there are some differences.
The OpenSSL component was named TIdSSLIOHandlerSocket.
TIdSMTP did not support STARTTLS yet. You would have to manage the SSLIOHandler'sPassThrough` property manually.
If you connect to port 587 for explicit TLS, you have to set PassThrough to true initially so you connect to the server unencrypted, then send the STARTTLS command manually and set PassThrough to false to activate encryption before sending any further SMTP commands.
Procedure SendMail();
begin
IdSMTP1.Host := 'smtp.gmail.com';
IdSMTP1.AuthenticationType := atLogin;
IdSMTP1.Port := 587;
IdSMTP1.Username := 'user#gmail.com';
IdSMTP1.Password := 'password';
IdSSLIOHandlerSocket1.PassThrough := True;
IdSMTP1.Connect;
try
IdSMTP1.SendCmd('STARTTLS', [220]);
IdSSLIOHandlerSocket1.PassThrough := False;
IdSMTP1.SendCmd('EHLO ' + IdSMTP1.LocalName);
IdSMTP1.Authenticate;
IdMessage1.Body.Add('Test Message');
IdMessage1.From.Address := 'frommail#gmail.com';
IdMessage1.Recipients.EMailAddresses := 'tomail#gmail.com';
IdMessage1.Subject := 'Hi';
try
IdSMTP1.Send(IdMessage1);
except
ShowMessage('Error : email not send');
end;
finally
IdSMTP1.Disconnect;
end;
end;
If you connect to port 465 for implicit SSL, all you have to do is set PassThrough to false before connecting to the server. The connection will be initially encrypted before sending any SMTP commands at all, no STARTTLS needed.
Procedure SendMail();
begin
IdSMTP1.Host := 'smtp.gmail.com';
IdSMTP1.AuthenticationType := atLogin;
IdSMTP1.Port := 465;
IdSMTP1.Username := 'user#gmail.com';
IdSMTP1.Password := 'password';
IdSSLIOHandlerSocket1.PassThrough := False;
IdSMTP1.Connect;
try
IdMessage1.Body.Add('Test Message');
IdMessage1.From.Address := 'frommail#gmail.com';
IdMessage1.Recipients.EMailAddresses := 'tomail#gmail.com';
IdMessage1.Subject := 'Hi';
try
IdSMTP1.Send(IdMessage1);
except
ShowMessage('Error : email not send');
end;
finally
IdSMTP1.Disconnect;
end;
end;

Answer 2

Thanks, Here I am using delphi 7.0 it will support TIdSSLIOHandlerSocketOpenSSL dll, so i can change the coding as like this. Since i got the same error message in this code.
Procedure SendMail();
var Resp : integer;
begin
IdSMTP1.Host :='smtp.gmail.com';
IdSMTP1.AuthenticationType:= atLogin;
IdSMTP1.Port := 587;
IdSMTP1.Username := 'user#gmail.com';
IdSMTP1.Password := 'password';
IdSMTP1.Connect;
if IdSMTP1.Connected then
Begin
Resp:= -1;
Resp:= IdSMTP1.SendCmd('STARTTLS',Resp);
IdMessage1.Body.Add('Tets Message');
IdMessage1.From.Address := 'frommail#gmail.com';
IdMessage1.Recipients.EMailAddresses := 'tomail#gmail.com';
IdMessage1.Subject := 'Hi';
try
IdSMTP1.Send(IdMessage1);
except
ShowMessage('Error : email not send');
end;
IdSMTP1.Disconnect;
end;
end;

Answer 3

I was helped:
When sending mail, a server error occurs:
'501 Syntactically invalid EHLO argument (s)' (error code 0x800CCC63).
This error occurs if the name of the computer (running Windows) contains invalid characters:
(`` {_} '', Russian letters or spaces).
Have a look on naming files
It should be changed via:
Control Panel> Network> Authentication.
It is also necessary to check the name specified through:
Control Panel> Network> TCP