Use of hash of hashes for extracting data - perl

Question

I am new to perl and am trying to understand hashes. I've tried using a basic hash and its working. I am now trying to extract data using a hash of hashes. E.g I have a text file (input.txt) that contains some random information. How can I extract the required information using a hash of hashes structure.
input.txt
hi how r you this is sample .txt. you can use it for learning hash and hash of hashes. Let say I have cell ("name") and it has value as below
cell ("name"){
pin : A, B;
function: A+B;
value: 0.435;
}
I want to extract cell data in following format.
Output
Cell Pin Value
name A 0.435
I tried this:
while(<$fh>)
{
if(/ cell \(/){$hash{cell} //=$_;}
elsif(/ pin \(/){$hash{pin} //=$_;}
elsif(/ value :/){$hash{value} //=$_;}
}
use Data::Dump;
dd \%hash;
This will give only one entry in hash form. How can I get all these matches available in the input file.

Answer 1

Firstly, you need some way to avoid the text commentary at the start of the file. You could just skip the first line, but then random text that appears elsewhere will mess things up. What would be better is to look for the relevant data but happily ignore any other text no matter where it appears.
Notice that the text commentary contains relevant-looking data: cell ("name") but there is no { on the end of the line. You could use that to distinguish between the commentary and the data but that's perhaps a little too flexible. Probably better to insist on the { as well as whitespace only before the cell declaration.
Once inside a cell, it's reasonable to insist on having no comments. We can then just iteratively read lines and split on the ":" until we reach the }. Combined with some general advice;
Separate regex definition from regex use.
Test your matches before using the capture variables; and
Use 'extended mode' regexes which allow whitespace in the regex
This all gives us;
#!/usr/bin/env perl
use v5.12;
use Data::Dumper qw(Dumper);
my $cell_name_re = qr/ ^ \s* cell \s* \( \s* "(\w+)" \) \s* { /x;
my $cell_data_re = qr/ ^ \s* ([^:]+) : (\N+) \n /x;
my $closing_curly_re = qr/ ^ \s* } /x;
my %data ;
while (<>) {
next unless /$cell_name_re/ ;
my $cell_name = $1 ;
my %cell_hash ;
while (<>) {
if ( /$cell_data_re/ ) {
$cell_hash{ $1 } = $2 ;
}
elsif ( /$closing_curly_re/ ) {
$data{ $cell_name } = \%cell_hash ;
last ; # exit the inner loop
}
else {
warn "Don't understand line $. - ignoring" ;
}
}
}
print Dumper( \%data );
exit 0;
There are two key things here - firstly, %cell_hash is declared inside the first loop which ensures we get a new %cell_hash each time through; and when we insert %cell_hash into the global %data we take a reference to it with \. Running it the input data above yields;
{
'name' => {
'function' => ' A+B;',
'value' => ' 0.435;',
'pin ' => ' A, B;'
}
};