Infix expression calculator racket - racket

Question

So i got this code:
#lang pl
#| BNF for the AE language:
<AE> ::= <num>
| { + <AE> <AE> }
| { - <AE> <AE> }
| { * <AE> <AE> }
| { / <AE> <AE> }
|#
;; AE abstract syntax trees
(define-type AE
[Num Number]
[Add AE AE]
[Sub AE AE]
[Mul AE AE]
[Div AE AE])
(: parse-sexpr : Sexpr -> AE)
;; to convert s-expressions into AEs
(define (parse-sexpr sexpr)
(match sexpr
[(number: n) (Num n)]
[(list '+ lhs rhs)
(Add (parse-sexpr lhs) (parse-sexpr rhs))]
[(list '- lhs rhs)
(Sub (parse-sexpr lhs) (parse-sexpr rhs))]
[(list '* lhs rhs)
(Mul (parse-sexpr lhs) (parse-sexpr rhs))]
[(list '/ lhs rhs)
(Div (parse-sexpr lhs) (parse-sexpr rhs))]
[else
(error 'parse-sexpr "bad syntax in ~s" sexpr)]))
(: parse : String -> AE)
;; parses a string containing an AE expression to an AE AST
(define (parse str)
(parse-sexpr (string->sexpr str)))
(: eval : AE -> Number)
;; consumes an AE and computes the corresponding number
(define (eval expr)
(cases expr
[(Num n) n]
[(Add l r) (+ (eval l) (eval r))]
[(Sub l r) (- (eval l) (eval r))]
[(Mul l r) (* (eval l) (eval r))]
[(Div l r) (/ (eval l) (eval r))]))
(: run : String -> Number)
;; evaluate an AE program contained in a string
(define (run str)
(eval (parse str)))
you can test and run is with run (+ 3 5) and the you will get 8.
my mission is to change the code so i can do run (3 + 5)
so i change the parse-sexpr function who build the tree it self to:
(: parse-sexpr : Sexpr -> AE)
;; to convert s-expressions into AEs
(define (parse-sexpr sexpr)
(match sexpr
[(number: n) (Num n)]
[(list lhs '+ rhs)
(Add (parse-sexpr lhs) (parse-sexpr rhs))]
[(list lhs '- rhs)
(Sub (parse-sexpr lhs) (parse-sexpr rhs))]
[(list lhs '* rhs)
(Mul (parse-sexpr lhs) (parse-sexpr rhs))]
[(list lhs '/ rhs)
(Div (parse-sexpr lhs) (parse-sexpr rhs))]
[else
(error 'parse-sexpr "bad syntax in ~s" sexpr)]))
I can still compile the code, but if i will do run (+ 5 3) i will get 8 and if i try to run (5 + 3) i'm getting:
Type Checker: Cannot apply expression of type Positive-Byte, since
it is not a function type in: (5 + 3)
why doe's this happend?

Answer 1

This is an issue of what is an expression in typed racket, vs. what is an expression in your language. In your language, (5 + 3) is an expression, but in typed racket, it's a type error. So you need to represent (5 + 3) as data in typed racket.
One common way to do this, as #soegaard pointed out, is to put a quote in front of it, like this: '(5 + 3). Though I hate writing it like that. What it really is, is (list 5 '+ 3). So you can pass it to your new parse-sexpr function to get
> (parse-sexpr (list 5 '+ 3))
- : AE
(Add (Num 5) (Num 3))
Then you can pass that value to your eval function to get
> (eval (Add (Num 5) (Num 3)))
- : Number
8
Composed together:
> (eval (parse-sexpr (list 5 '+ 3)))
- : Number
8
But your run function takes a string, passes it to string->sexpr then passes that to parse-sexpr and then your eval function. So what you probably meant to do all along was this:
> (eval (parse-sexpr (string->sexpr "{5 + 3}")))
- : Number
8
> (run "{5 + 3}")
- : Number
8
Assuming that string->sexpr takes expressions with curly braces like that. What you were doing was (run (5 + 3)), which treats (5 + 3) as a typed racket expression. What you wanted was (run "{5 + 3}"), which treats (5 + 3) as an expression in your language, which is represented as data in typed racket.

Answer 2

Did you by chance write
(run (+ 5 3))
instead of
(run '(+ 5 3))
?
If you write (run (+ 5 3)) then Racket will compute (+ 5 3) first, and then call (run 8). If you write (run (5 + 3)) then Racket will attempt to evaluate (5 + 3) and that gives the error you see: the number 5 is not a function type, so it can not be used as in (5 ...).