Progress 4gl Secure Socket Authentication - sockets

Question

Currently attempting to perform a socket connection to a host that has authentication setup using the username:password#domain syntax. The following curl request works fine when run via command line:
/opt/pware/bin/curl -s -v -S -k -X POST -d #/test/worldpay.xml https://username:password#secure-test.worldpay.com/jsp/merchant/xml/paymentService.jsp
The problem lies when attempting to post the same worldpay.xml payload file using progress secure socket. My socket connects using the following:
DEFINE VARIABLE vhSocket AS HANDLE NO-UNDO.
CREATE SOCKET vhSocket.
vhSocket:CONNECT('-H test.worldpay.com -S 443 -ssl -nohostverify') NO-ERROR.
IF vhSocket:CONNECTED() EQ FALSE THEN
DO:
Message "COULD NOT CONNECT".
vhSocket:DISCONNECT().
DELETE OBJECT vhSocket NO-ERROR.
RETURN.
END.
ELSE
Message "CONNECTED!".
I am setting up my header as follows once the socket connection is opened:
ASSIGN
vRequest = 'POST ' +
username + ":" + password + "#" + "/jsp/merchant/xml/paymentService.jsp" +
' HTTPS/1.1' + chr(13) + chr(10) +
'Connect: close' + chr(13) + chr(10) +
'Host: ' + "secure-test.worldpay.com" + chr(13) + chr(10) +
'Content-Length: ' + string(LENGTH(postdata,"raw")) + chr(13) + chr(10) +
'Content-Type: text/xml' + chr(13) + chr(10) +
chr(13) + chr(10) +
postData +
chr(13) + chr(10).
set-byte-order(vData) = BIG-ENDIAN.
set-size(vData) = LENGTH(vRequest,"raw").
put-string(vData,1,LENGTH(vRequest,"raw")) = vRequest.
vReturnCode = vhSocket:WRITE(vData, 1, LENGTH(vRequest,"raw")).
Any help on figuring out how the header should be structured or how to perform basic authentication over Secure Sockets in Progress would be greatly appreciated. Thanks guys!

Answer 1

For http(s) basic authentication, you don't POST the username as part of the URL.
See https://en.wikipedia.org/wiki/Basic_access_authentication#Client_side
This is what we use in our http client, you'll have to change the call to AddHttpHeader to code that send that header line to the server socket.
/*------------------------------------------------------------------------------
Purpose: Adds a basic authorization header to the request
Notes:
#param pcUserName The UserName to use for basic authorization
#param pcPassword The password to use for basic authorization
------------------------------------------------------------------------------*/
METHOD PUBLIC VOID SetBasicAuthorization (pcUserName AS CHARACTER,
pcPassword AS CHARACTER):
DEFINE VARIABLE cBase64 AS LONGCHAR NO-UNDO.
DEFINE VARIABLE mAuthorization AS MEMPTR NO-UNDO .
ASSIGN cBase64 = SUBSTITUTE ("&1:&2":U, pcUserName, pcPassword) .
SET-SIZE (mAuthorization) = LENGTH (cBase64) .
PUT-STRING (mAuthorization, 1, LENGTH (cBase64)) = cBase64 .
ASSIGN cBase64 = BASE64-ENCODE (mAuthorization) .
AddHttpHeader (SUBSTITUTE ("Authorization Basic &1":U, cBase64)) .
FINALLY:
SET-SIZE (mAuthorization) = 0 .
END FINALLY.
END METHOD .
So in your case, try this:
ASSIGN
vRequest = 'POST ' + "/jsp/merchant/xml/paymentService.jsp" +
' HTTPS/1.1' + chr(13) + chr(10) +
'Connect: close' + chr(13) + chr(10) +
'Host: ' + "secure-test.worldpay.com" + chr(13) + chr(10) +
'Content-Length: ' + string(LENGTH(postdata,"raw")) + chr(13) + chr(10) +
'Content-Type: text/xml' + chr(13) + chr(10) +
'Authorization: Basic ' + cBase64 + chr(13) + chr(10) +
chr(13) + chr(10) +
postData +
chr(13) + chr(10).