Is there any function to convert long decimal number in to hexadecimal? - perl

Question

I have a need to convert a long decimal number :14245138929982432 in to hexadecimal value whose value is 329BE0DDB29BE0.
But when i am trying to use below piece of code i am getting result as FFFFFFFF.
$l_KeyExpected_UL=14245138929982432;
$hexadeci = sprintf '%X', $l_KeyExpected_UL;
print $hexadeci."\n";\
can Any one please help on this.

Answer 1

You can use the Math::BigInt module, which does all the heavy-lifting behind the bigint pragma
You can't use sprintf under bigint to convert large decimals to hex because its conversions aren't overloaded, but Math::BigInt objects have an as_hex method which returns the number expressed as a hex string, prefixed with 0x
This program wraps the conversion in a subroutine bigint_to_hex, which removes the 0x prefix and changes lower case to upper case
It is unusual now to encounter an installation of Perl that won't handle 64-bit values anyway. But this method will work with any decimal string, as I have demonstrated by converting a value of 1.2E40 as well as the value in your question
It's vital that you pass big integers as strings, because numeric literals will be converted to floating point by the compiler if they exceed the width of an ordinary integer. My program also prints the hex equivalent of the same 1.2E40 value without quotation marks so that you can see the difference
use strict;
use warnings 'all';
use feature 'say';
use Math::BigInt;
my $l_KeyExpected_UL = '14245138929982432';
say bigint_to_hex($l_KeyExpected_UL);
say bigint_to_hex('12345678901234567890123456789012345678901');
say bigint_to_hex(12345678901234567890123456789012345678901);
say bigint_to_hex(1.2E40);
sub bigint_to_hex {
my $hex = Math::BigInt->new(shift)->as_hex;
$hex =~ s/^0x//;
uc $hex;
}
output
329BE0DDB29BE0
2447DB449988978536BF5BBBE40E766C35
2447DB449988B214BEA48F651CA8000000
2343CBEEEA6F2C193478C00E0000000000

Answer 2

If you have a build of Perl with 64-bit integers
A Perl build with 64-bit ints will display the following:
$ perl -V:ivsize
ivsize='8';
If this is what you have, you can simply use
my $i = 14245138929982432;
my $hex = sprintf('%X', $i);
If you have a build of Perl that may not have 64-bit integers
That number requires at least 56 bits to store.
Math::Int64 allows you to access native 64-bit ints.
use Math::Int64 qw( uint64 int64_to_hex );
# Note that the number is provided as a string!
my $i = uint64('14245138929982432');
my $hex = int64_to_hex($i);
You could also use an arbitrary precision library such as Math::BigInt, but it will be necessarily slower. If you're going to do some number crunching with 64-bit ints, you definitely want Math::Int64 instead of Math::BigInt.