Issue with accessors in Drools - class

Question

I came across a particular scenario when updating composed objects in Drools:
declare A
#propertyReactive
flag: Boolean
end
declare B
flag: Boolean
end
declare C
#propertyReactive
attrA: A
attrB: B
end
rule "Create A"
when
not A()
then
insert(new A());
System.out.println("OBJECT A CREATED");
end
rule "Create B"
when
not B()
then
insert(new B());
System.out.println("OBJECT B CREATED");
end
rule "Create C"
when
$A:A()
$B:B()
not C()
then
insert(new C($A,$B));
System.out.println("OBJECT C CREATED");
end
rule "Modify A"
when
$A:A(flag == false)
C()
then
modify($A) {setFlag(true)};
String $output = "Now A is " + $A.getFlag();
System.out.println($output);
end
rule "Print C when C is False"
when
C($A:attrA, attrA.flag == false, $B:attrB)
then
String $output = "A is " + $A.getFlag() + " and B is " + $B.getFlag();
System.out.println($output);
end
rule "Print C when C is True"
when
C($A:attrA, attrA.flag == true, $B:attrB)
then
String $output = "A is " + $A.getFlag() + " and B is " + $B.getFlag();
System.out.println($output);
end
rule "Print C when C is True 2"
when
C($A:attrA, $B:attrB)
A(this == $A, flag == true)
then
String $output = "2 A is " + $A.getFlag() + " and B is " + $B.getFlag();
System.out.println($output);
end
The output is:
OBJECT A CREATED
OBJECT B CREATED
OBJECT C CREATED
A is false and B is false
Now A is true
2 A is true and B is false
So I have the following questions:
Why is rule "Print C when C is True" not firing?
Why do I need to rewrite that rule as "Print C when C is True 2" to make it work?
Does anybody have an explanation for this?
It looks like Drools has an issue in working with accessors of nested classes...
Thank you very much.

Answer 1

Drools only reacts on changes performed to the objects used in your patterns and not to any nested object reference they may contain. And this is not entirely true either.
When you modify a fact in Drools (or any of its nested object references), you have the option to let Drools know about this modification or not. In your case, you are never notifying Drools about them. That is why your rules depend on the (not deterministic) evaluation order.
If you want to let Drools "know" about the modifications on a fact, then you must use the modify or update functions in the RHS of the rules where these modifications happen.
In your particular case, you have not only nested objects, but nested facts: A and C. Even if A is a fact, changes on A (even if properly notified to Drools) will never trigger the re-evaluation of a pattern like this:
C(attrA.flag == true)
The reason why is because the type of the pattern is C and not A. In these kind of scenarios, a rule written like your Print C when C is True 2 rule is a better approach.
Hope it helps,