Passing the file location from command line - command-line

Question

Below is my VBScript code to send an email with a file attached. The file is present at a location which I need to grab when sending the email.
Set objMessage = CreateObject("CDO.Message")
Set args = WScript.Arguments
Set arg1 = args.Item(0)
objMessage.Subject = "Sample subject"
objMessage.From = "test#gmail.com"
objMessage.To = "test2#gmail.com"
objMessage.TextBody = "Please see the error logs attached with this email"
objMessage.AddAttachment ""&arg1&""
'==This section provides the configuration information for the remote SMTP server.
'==Normally you will only change the server name or IP.
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
'Name or IP of Remote SMTP Server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "hostname"
'Server port (typically 25)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objMessage.Configuration.Fields.Update
'==End remote SMTP server configuration section==
objMessage.Send
To run this script through command line I use:
>cscript sendemail.vbs D:\users\me\Desktop\readme.txt
When I run this I get an error saying:
D:\Users\me\Desktop\sendemail.vbs(3, 1) Microsoft VBScript runtime error: Object required: '[string: "D:\Users\me\Desk"]'
Any suggestions what could be wrong with this?

Answer 1

The error message actually says it all. While the Arguments collection is an object, its first element is not. It's a string, which in VBScript is a primitive data type. The Set keyword is exclusively for assigning objects to variables. Primitive data types are assigned by just using the assignment operator.
Change this:
Set arg1 = args.Item(0)
into this:
arg1 = args.Item(0)
and the error will disappear.